GLSLでテクスチャの色合いを変更するにはどうすればいいですか？

Question

GLSL（フラグメントシェーダ）を使用して2D OpenGLテクスチャの色相を効率的に変更する方法はありますか？

誰かにコードがありますか？

UPDATE：これはuser1118321提案に起因するコードである：

uniform sampler2DRect texture; 
const mat3 rgb2yiq = mat3(0.299, 0.587, 0.114, 0.595716, -0.274453, -0.321263, 0.211456, -0.522591, 0.311135); 
const mat3 yiq2rgb = mat3(1.0, 0.9563, 0.6210, 1.0, -0.2721, -0.6474, 1.0, -1.1070, 1.7046); 
uniform float hue; 

void main() { 

vec3 yColor = rgb2yiq * texture2DRect(texture, gl_TexCoord[0].st).rgb; 

float originalHue = atan(yColor.b, yColor.g); 
float finalHue = originalHue + hue; 

float chroma = sqrt(yColor.b*yColor.b+yColor.g*yColor.g); 

vec3 yFinalColor = vec3(yColor.r, chroma * cos(finalHue), chroma * sin(finalHue)); 
gl_FragColor = vec4(yiq2rgb*yFinalColor, 1.0); 
} 

そして、これは、基準と比較した結果である：私は私を切り替えることを試みた

Q内のatanしかし結果は間違っても約0°

何かヒント？

比較のために必要であれば

が、これはオリジナルの無修正画像です：何@awoodland言うことは正しいです

Answer 1

ますが、その方法は、輝度の変化に問題が発生する可能性があり、私は信じています。

HSVおよびHLSカラーシステムは、いくつかの理由で問題があります。私はこれについて色彩科学者と最近話しました.YIQまたはYCbCr空間に変換し、それに応じて彩度チャンネル（I & Q、またはCb & Cr）を調整することをお勧めしました。 （あなたがそのhereとhereを行う方法を学ぶことができます。）

したら、それらのスペースの1つに、あなたはhue = atan(cr/cb)を行うことによって、クロマチャネルによって形成された角度からの色相を得ることができます（CBを監視== 0）。これにより、ラジアン単位の値が得られます。色相回転量を加えて回転させるだけです。これをやったら、chroma = sqrt(cr*cr+cb*cb)で彩度の大きさを計算することができます。 RGBに戻すには、Cr = chroma * sin (hue),Cb = chroma * cos (hue)を使用して新しいCbとCr（またはI & Q）を計算します。その後、上記のWebページに記載されているようにRGBに変換し直します。

編集：ここで私がテストしたソリューションは、私の参照と同じ結果を与えるようです。おそらく、マトリックス乗算にドットの製品の一部を折りたたむことができます。

uniform sampler2DRect inputTexture; 
uniform float hueAdjust; 
void main() 
{ 
    const vec4 kRGBToYPrime = vec4 (0.299, 0.587, 0.114, 0.0); 
    const vec4 kRGBToI  = vec4 (0.596, -0.275, -0.321, 0.0); 
    const vec4 kRGBToQ  = vec4 (0.212, -0.523, 0.311, 0.0); 

    const vec4 kYIQToR = vec4 (1.0, 0.956, 0.621, 0.0); 
    const vec4 kYIQToG = vec4 (1.0, -0.272, -0.647, 0.0); 
    const vec4 kYIQToB = vec4 (1.0, -1.107, 1.704, 0.0); 

    // Sample the input pixel 
    vec4 color = texture2DRect (inputTexture, gl_TexCoord [ 0 ].xy); 

    // Convert to YIQ 
    float YPrime = dot (color, kRGBToYPrime); 
    float I  = dot (color, kRGBToI); 
    float Q  = dot (color, kRGBToQ); 

    // Calculate the hue and chroma 
    float hue  = atan (Q, I); 
    float chroma = sqrt (I * I + Q * Q); 

    // Make the user's adjustments 
    hue += hueAdjust; 

    // Convert back to YIQ 
    Q = chroma * sin (hue); 
    I = chroma * cos (hue); 

    // Convert back to RGB 
    vec4 yIQ = vec4 (YPrime, I, Q, 0.0); 
    color.r = dot (yIQ, kYIQToR); 
    color.g = dot (yIQ, kYIQToG); 
    color.b = dot (yIQ, kYIQToB); 

    // Save the result 
    gl_FragColor = color; 
} 

Answer 2

Andrea3000、ネット上YIQ例を比較する際に、私はあなたの投稿に出くわしたが、私はの「更新」のバージョンに問題があると思いますあなたのコード....私はあなたの 'mat3'の定義は、列/行の順序でフリップ/フロップされていると確信しています...（おそらくあなたはまだトラブルを抱えていた理由です）...

FYI： ： "より多くの値の場合、行列は列の大きな順序で塗りつぶされます。つまり、最初のX値は最初の列、2番目のX値は次の列です。参照：http://www.opengl.org/wiki/GLSL_Types

mat2(
float, float, //first column 
float, float); //second column