proc gplot 255件以上の被験者のスパゲッティプロット

Question

こんにちは私はスパゲッティプロットをしようとするときに質問があります。私はそれぞれの主題が異なる記号や色を持つことを望んでいません。私はちょうど黒い線分を持つ必要があります。誰もが同じシンボルステートメントを作成してgplotを使うだけで、より少ない件数でうまくやることができましたが、255人以上の被験者で行うと、SASは255個以上のシンボルを持つことができないと訴えています。これを行う方法はありますか？

data _null_; 
set ptdata&trtn. end=eof; 
retain patcount 0; 
by usubjid; 
if first.usubjid then patcount+1; 
if last.usubjid then lastgfr='Y'; 
    call symput('sym'||trim(left(patcount)), 
    'symbol'||trim(left(patcount)) 
    || ' '|| 'c=black'|| ' '||'v=Dot'||' ' 
    || 'i=join'|| ' ' || 'line=1' || 'width=1' ||';'); 
if eof then call symput('total',patcount); 
run; 

%macro symbol; 
%do j=1 %to &total; 
&&sym&j 
%end; 
%mend symbol; 

%symbol 

proc gplot data = ptdata&trtn. ; 
    plot change_since_bl*FUPTIME=usubjid /haxis=axis3 vaxis=axis4 href=0 nolegend; 
    format change_since_bl 8. ;*/ 
run ; 

Answer 1

私はPROC SGPLOTを使用することになり、それがGPLOTのような255に限定されるものではないが、使用する方が簡単です。

はこれを試してみてください：

data test; 
do person=1 to 256; 
    value = 100; 
    do time=0 to 10; 
     value = value + rannor(1); 
     output; 
    end; 
end; 
run; 

proc sgplot data=test noautolegend; 
series x=time y=value/group=person lineattrs=(color=black pattern=dash) ; 
run; 

私は、これはあなたが探しているものだと思います。