pm3dのサムパレット

Question

多倍長では、異なるパレットカラーの3つのマップを描画します（下のコードを参照）。 列14,15,16の値に応じて、赤い部分、青い部分、緑の部分、および赤+青+緑の組み合わせの3つの他の部分、すなわち3つの他の部分の合計を4倍にしたい。

set view map; set size square 
set xlabel "delta mu Al" 
set ylabel "delta mu Mn" 
set zlabel "fraction atomique" 

set multiplot layout 2,2 
set title "Fer" 
set palette defined (0 "white", 1 "red") 
splot "res700.dat" u 3:4:($16/3456) t "Fe" with pm3d 

set title "Alu" 
set palette defined (0 "white", 1 "green") 
splot "res700.dat" u 3:4:($14/3456) t "Fe" with pm3d 

set title "Mn" 
set palette defined (0 "white", 1 "blue") 
splot "res700.dat" u 3:4:($15/3456) t "Fe" with pm3d 

unset multiplot 

Answer 1

rgb variableを使用してください。無信号の色として黒を使用すると、これは与える：

set view map; set size square 
set xlabel "delta mu Al" 
set ylabel "delta mu Mn" 
set zlabel "fraction atomique" 

set isosample 100 
Fe(x,y)=x*y 
Al(x,y)=(1-x)*y 
Mn(x,y)=x*(1-y) 

set multiplot layout 2,2 
set title "Fer" 
set palette defined (0 "black", 1 "red") 
splot [0:1][0:1] "++" u 1:2:(Fe($1,$2)) t "Fe" with pm3d 

set title "Alu" 
set palette defined (0 "black", 1 "green") 
splot [0:1][0:1] "++" u 1:2:(Al($1,$2)) t "Al" with pm3d 

set title "Mn" 
set palette defined (0 "black", 1 "blue") 
splot [0:1][0:1] "++" u 1:2:(Mn($1,$2)) t "Mn" with pm3d 

set title "" 
rgb(r,g,b) = 65536 * int(255*r) + 256 * int(255*g) + int(255*b) 
unset colorbox 
splot [0:1][0:1] "++" u 1:2:(rgb(Fe($1,$2),Al($1,$2),Mn($1,$2))) t "" with pm3d lc rgb variable 

unset multiplot