gnuplot - zminをzmaxと同じにする方法

Question

z軸上のスケーリングの出力をxy平面上で対称にする方法：zmax = zmin、z軸の自動スケールをオンにしていますか？ （GNUplotという紹介5.0）

resulting graph - 3d-polar.png

を使用することができるこのgnuplotで使われている可能性、またはcbrangeの唯一の一定の範囲がありますか？

極性ヒートマッププロットのために使用されている例：

reset 
set terminal pngcairo size 800,800 
set output '3d-polar.png' 
set lmargin at screen 0.05 
set rmargin at screen 0.85 
set bmargin at screen 0.1 
set tmargin at screen 0.9 

set pm3d map 
unset key 
set multiplot 

set parametric 
set grid xtics ytics 

set angles degree 
set autoscale xfix 
set autoscale yfix 
set autoscale zfix 
set palette model RGB defined (0"black", 1"white", 2"grey") 
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3 
unset multiplot 

_FullWV.datファイルがhereです。

Answer 1

statsを使用して、3番目の列の最小値と最大値を抽出し、それに応じてcbrangeを定義することができます。

reset 
set terminal pngcairo size 800,800 
set output '3d-polar.png' 
set lmargin at screen 0.05 
set rmargin at screen 0.85 
set bmargin at screen 0.1 
set tmargin at screen 0.9 

set pm3d map 
unset key 
set multiplot 

stats '_FullWV.dat' using 3 
max(a,b) = (a>b) ? a : b 

Z_MAX = max(-STATS_min, STATS_max) 

set parametric 
set grid xtics ytics 

set angles degree 
set autoscale xfix 
set autoscale yfix 
#set zrange [-Z_MAX : Z_MAX] 
set cbrange [-Z_MAX : Z_MAX] 

set palette model RGB defined (0"black", 1"white", 2"grey") 
splot '_FullWV.dat' u ($2*cos($1)):($2*sin($1)):3 
unset multiplot