このXSLTは非効率的ですか？

Question

my last question about translating an XML fileから回答がありました。私は別の解決策を考え出しましたが、最後の2つの選択肢が最適ではないという気持ちがあります。これは、より良い方法で、あるいはより効率的に行うことができますか？

スタイルシート：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:param name="pFrom" select="'en'"/> 
    <xsl:param name="pTo" select="'de'"/> 


    <xsl:variable name="translations" select="document('translations.xml')"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="@name"> 
    <xsl:variable name="thisname" select="." /> 

    <xsl:variable name="entry" select="$translations/translations/entry[attribute::node()[name()=$pFrom and $thisname=.]]"></xsl:variable> 
    <xsl:attribute name="name" select="$entry/attribute::node()[local-name() = $pTo]"></xsl:attribute> 
    </xsl:template> 
</xsl:stylesheet> 

ソース：

<?xml version="1.0" encoding="UTF-8"?> 
<grammar> 
    <element name="table" /> 
    <element name="chair" /> 
</grammar> 

と翻訳ファイル（translations.xml）：

<?xml version="1.0" encoding="UTF-8"?> 
<translations> 
    <entry en="table" de="Tisch" fr="Table" /> 
    <entry en="chair" de="Stuhl" fr="Chaise"/> 
</translations> 

結果は次のとおりです。

<grammar> 
    <element name="Tisch"/> 
    <element name="Stuhl"/> 
</grammar> 

例： 'en'から 'de'に移動し、ソースファイルの最初のname属性（ 'table'）にあるとき、enエントリの翻訳ファイルを調べます。en = "table"名前の「de」属性を選択します。

Answer 1

使用キー：

<xsl:key name="en" match="translations/entry" use="@en"/> 
<xsl:key name="de" match="translations/entry" use="@de"/> 
<xsl:key name="fr" match="translations/entry" use="@fr"/> 

、その後

<xsl:template match="@name"> 
    <xsl:attribute name="name" select="key($pFrom, current(), $translatations)/@*[local-name() = $pTo]"/> 
    </xsl:template> 

（私はあなたがXSLT 2.0を使用すると仮定します）。