Common LispのPython enumerate（）analog

Question

リストにマップするが、リスト内の要素インデックスを追跡したい。

私はの線に沿って何かを行うことができますPythonで

：私はの線に沿って何かにそれを翻訳しようとしていた

map(lambda (idx, elt): "Elt {0}: {1}".format(idx, elt), enumerate(mylist)) 

を：

(mapcar-something (lambda (elt idx) (format nil "Elt ~D: ~S" idx elt)) 
        '(a b c d)) 

期待される結果：

("Elt 0: A" "Elt 1: B" "Elt 2: C" "Elt 3: D") 

しかし、私が使用すべきmapcar-something関数を見つけることができません。それを自分で実装する必要がありますか（ループ経由か多分）。

Answer 1

Common LispのLOOPマクロを自動的に保つことができますインデックスのトラック。

(loop for elt in '(a b c d) and idx from 0 
     collect (operation-on idx elt)) 

LOOP 1によって自動的増加fromで初期化変数。 andによってそれらが導入された場合、両方の割り当て（配列の要素とインデックス）はネストではなく一度に起こります。

したがって、列挙関数はのラインに沿って次のようになりますのCommon Lispの表現で

(defun enumerate (list &optional (first-index 0)) 
    (loop for elt in list and idx from first-index 
    collect (cons idx elt))) 

、おそらくの線に沿ってマクロを定義することは有用であろう：

(defmacro with-enumerated-list ((list elt idx &key (first-index 0)) &body body) 
    `(loop for ,elt in ,list and ,idx from ,first-index 
    collect (progn ,@body))) 

この場合、列挙関数を次のように減らすことができます：

(defun enumerate (list &optional (first-index 0)) 
    (with-enumerated-list (list elt idx :first-index first-index) 
    (cons idx elt))) 

Answer 2

CL-USER 25 > (defun iota (n) 
       (loop for i below n collect i)) 
IOTA 

CL-USER 26 > (iota 4) 
(0 1 2 3) 

CL-USER 27 > (mapcar (lambda (elt idx) 
         (format nil "Elt ~D: ~S" idx elt)) 
        '(a b c d) 
        (iota 4)) 
("Elt 0: A" "Elt 1: B" "Elt 2: C" "Elt 3: D") 

または

CL-USER 28 > (loop for elt in '(a b c d) and idx from 0 
        collect (format nil "Elt ~D: ~S" idx elt)) 
("Elt 0: A" "Elt 1: B" "Elt 2: C" "Elt 3: D") 

Answer 3

あなたの元の例のように見える何かをしたい場合：

(defun enumerate (function list) 
    (let ((idx 0)) 
    (loop for elt in list 
     collect (funcall function elt idx) 
     do (incf idx)))) 

あなたの例を：

(enumerate (lambda (elt idx) (format nil "Elt ~D: ~S" idx elt)) 
      '(a b c d)) 
=> ("Elt 0: A" "Elt 1: B" "Elt 2: C" "Elt 3: D")