私は、Matlab言語の基本サブセットをC#、C++などに変換するためのレクサージェネレータを作成したいと思います。これを行うために、私はmatlabの正式な文法を含むドキュメントを探したいと思います。これを調査するのに少し時間を費やしていたので、数学はそれを提供していないようです。 誰もそのような文書がどこにあるのか知っていますか?Matlabの正式な文法はどこで見つけることができますか?
答えて
独自の正式な文法を書くための絶好の機会:)
にあなたがあなたの自己文法を書くことを選択しなければならない場合、私は正式なBNF文法を取るとデータ構造を構築することができBNFCをお勧めすることができますし、ためレクサー/パーサは、いくつかのターゲット言語(C/C++、C#、Java、Haskellなど)があります。これにより、多くの時間が節約され、文法の策定に専念できるようになります。そして、あなたの言語でコンバーターを実装することができます。
他に何もない場合、BNFCへのリンクには、BNF文法を定式化する方法に関するいくつかの助けと指針が含まれています。運が良かった!
アドバイスをいただき、ありがとうございます。私はfslexとfsyaccの使用を考えていました。 –
これは完全な文法ではなく、2000年のコンパイラコースにyacc-keable for matlabが提供されています。これにより、BNFとEBNFを簡単に作成できます。
primary_expression
: IDENTIFIER
| CONSTANT
| STRING_LITERAL
| '(' expression ')'
| '[' ']'
| '[' array_list ']'
;
postfix_expression
: primary_expression
| array_expression
| postfix_expression TRANSPOSE
| postfix_expression NCTRANSPOSE
;
index_expression
: ':'
| expression
;
index_expression_list
: index_expression
| index_expression_list ',' index_expression
;
array_expression
: IDENTIFIER '(' index_expression_list ')'
;
unary_expression
: postfix_expression
| unary_operator postfix_expression
;
unary_operator
: '+'
| '-'
| '~'
;
multiplicative_expression
: unary_expression
| multiplicative_expression '*' unary_expression
| multiplicative_expression '/' unary_expression
| multiplicative_expression '\\' unary_expression
| multiplicative_expression '^' unary_expression
| multiplicative_expression ARRAYMUL unary_expression
| multiplicative_expression ARRAYDIV unary_expression
| multiplicative_expression ARRAYRDIV unary_expression
| multiplicative_expression ARRAYPOW unary_expression
;
additive_expression
: multiplicative_expression
| additive_expression '+' multiplicative_expression
| additive_expression '-' multiplicative_expression
;
relational_expression
: additive_expression
| relational_expression '<' additive_expression
| relational_expression '>' additive_expression
| relational_expression LE_OP additive_expression
| relational_expression GE_OP additive_expression
;
equality_expression
: relational_expression
| equality_expression EQ_OP relational_expression
| equality_expression NE_OP relational_expression
;
and_expression
: equality_expression
| and_expression '&' equality_expression
;
or_expression
: and_expression
| or_expression '|' and_expression
;
expression
: or_expression
| expression ':' or_expression
;
assignment_expression
: postfix_expression '=' expression
eostmt
: ','
| ';'
| CR
;
statement
: global_statement
| clear_statement
| assignment_statement
| expression_statement
| selection_statement
| iteration_statement
| jump_statement
;
statement_list
: statement
| statement_list statement
;
identifier_list
: IDENTIFIER
| identifier_list IDENTIFIER
;
global_statement
: GLOBAL identifier_list eostmt
;
clear_statement
: CLEAR identifier_list eostmt
;
expression_statement
: eostmt
| expression eostmt
;
assignment_statement
: assignment_expression eostmt
;
array_element
: expression
| expression_statement
;
array_list
: array_element
| array_list array_element
;
selection_statement
: IF expression statement_list END eostmt
| IF expression statement_list ELSE statement_list END eostmt
| IF expression statement_list elseif_clause END eostmt
| IF expression statement_list elseif_clause
ELSE statement_list END eostmt
;
elseif_clause
: ELSEIF expression statement_list
| elseif_clause ELSEIF expression statement_list
;
iteration_statement
: WHILE expression statement_list END eostmt
| FOR IDENTIFIER '=' expression statement_list END eostmt
| FOR '(' IDENTIFIER '=' expression ')' statement_list END eostmt
;
jump_statement
: BREAK eostmt
| RETURN eostmt
;
translation_unit
: statement_list
| FUNCTION function_declare eostmt statement_list
;
func_ident_list
: IDENTIFIER
| func_ident_list ',' IDENTIFIER
;
func_return_list
: IDENTIFIER
| '[' func_ident_list ']'
;
function_declare_lhs
: IDENTIFIER
| IDENTIFIER '(' ')'
| IDENTIFIER '(' func_ident_list ')'
;
function_declare
: function_declare_lhs
| func_return_list '=' function_declare_lhs
;
Dave Wingateは素晴らしいスタート地点のようなAntlerのリソースを提供しています。 彼のREADMEファイルに記載されているように、彼には、転置演算子とその他のトリッキーないくつかの解析は含まれていません。 Matlabの(1999)以前のバージョンのトリッキーなビットのいくつかはまた、北西からのグループによって文書に記載されている
http://web.mit.edu/~wingated/www/resources.html
:ここでmparserリンクを参照。これにはEBNFのような記述が含まれています。また、いくつかの脚注のいくつかの厄介なビットについても概説しています。
http://www.ece.northwestern.edu/cpdc/pjoisha/MAGICA/CPDC-TR-9909-017.pdf
私は他のあまり関係のソースのカップルを集めてきましたが、stackoverflowのエディタのボットは、私が二つ以上のリンクを投稿するのに十分な評判ポイントを持っていないと言われます。
まず、Pythonで書かれたMATLAB - > Pythonコンバータsmop
を採用することができます。 PLY(Python lex
- yacc
)を使用しています。あなたが最初に興味のあるファイルはlexer.pyとparse.pyです。
this answerも参照してください。これは、MATLABからPythonへのコンバータの一覧です。
- 1. C90とC99の明示的な文法はどこで見つけることができますか?
- 2. どこでMicrosoft.Build.Utilities.v3.5を見つけることができます
- 3. フラッシュデバッグプロトコルの仕様はどこで見つけることができますか?
- 4. タイムゾーンの一覧はどこで表形式で見つけることができますか?
- 5. jsonファイルが不正な形式である - どこを見つけるか?
- 6. Visual StudioのC99の数式の実装はどこで見つけることができますか?
- 7. n2nコンセンサスアルゴリズム情報はどこで見つけることができますか?
- 8. Umbracoフリースキンはどこで見つけることができますか
- 9. stanford corenlpのSPIEDツールの実装はどこで見つけることができますか?論文では
- 10. 私はどこで.od形式のモデルを見つけることができますか?
- 11. どこで__sync_add_and_fetchのヘッダを見つけることができますか
- 12. どこでcpanelのphp.iniを見つけることができますか
- 13. UWPのどこでpingを見つけることができますか?
- 14. どこでneo4jのクイックチュートリアルを見つけることができますか?
- 15. どこで私のmySQLデータベースを見つけることができますか?
- 16. タイムゾーンの紹介をどこで見つけることができますか
- 17. どこでPythonのvtkドキュメントを見つけることができますか?
- 18. どこでmagento apiのログを見つけることができますか?
- 19. どこでCGALで.cppファイルを見つけることができますか?
- 20. JXTAでNetworkManager.RecursiveDelete()をどこで見つけることができますか?
- 21. どこでspiteでsqliteデータベースを見つけることができますか?
- 22. どこでメゾでサービスを見つけることができますか
- 23. C#文字列形式 - 正しい方法を見つけることができません
- 24. どこでiOSパスを見つけることができますか?
- 25. PIL SANEインターフェース:どこで見つけることができますか?
- 26. どこでDjango get_absolute_urlを見つけることができますか?
- 27. どこで良いUIを見つけることができますか?
- 28. どこで良いRobocodeチュートリアルを見つけることができますか?
- 29. どこでssbdiagnoseを見つけることができますか
- 30. どこでC++ csoundチュートリアルを見つけることができますか?
私はMathworksがMatlabの正式な文法を定義していないと強く疑っています。私はこれに答えて見守ります。 –
OctaveはMatlabの文法を解析します。彼らが何をしたのかを確認する価値があるかもしれません。 –
Octaveソースの[lex file](http://hg.savannah.gnu.org/hgweb/octave/file/c1f9b54350f9/src/lex.ll)が役立ちます。私はまた、[antlパーサー](http://www.antlr.org/pipermail/antlr-interest/2011-September/042551.html)を見て、matlabをCとJavaに変換しました。 –