文字列からのDelphi Firemonkeyコンポーネントのランタイム作成

Question

最終的にRTTIを使用してフォームの子としてビジュアルコンポーネントを実行時に作成するにはどうすればよいですか？ 私が得たすべてがTValueインスタンスです...

t := (ctx.FindType(Edit1.Text) as TRttiInstanceType); 
inst:= t.GetMethod('Create').Invoke(t.MetaclassType,[Form1]); 

ありがとうございました！ TRttiMethod.Invoke()を使用して

Answer 1

純粋にRTTIのアプローチは、このようになります：TRttiMethod.Invoke()を使用していません

var 
    ctx: TRttiContext; 
    t: TRttiInstanceType; 
    m: TRttiMethod; 
    params: TArray<TRttiParameter>; 
    v: TValue; 
    inst: TControl; 
begin 
    t := ctx.FindType(Edit1.Text) as TRttiInstanceType; 
    if t = nil then Exit; 
    if not t.MetaclassType.InheritsFrom(TControl) then Exit; 
    for m in t.GetMethods('Create') do 
    begin 
    if not m.IsConstructor then Continue; 
    params := m.GetParameters; 
    if Length(params) <> 1 then Continue; 
    if params[0].ParamType.Handle <> TypeInfo(TComponent) then Continue; 
    v := m.Invoke(t.MetaclassType, [TComponent(Form1)]); 
    inst := v.AsType<TControl>(); 
    // or: inst := TControl(v.AsObject); 
    Break; 
    end; 
    inst.Parent := ...; 
    ... 
end; 

Aはるかに簡単な方法は、次のようになります。

type 
    // TControlClass is defined in VCL, but not in FMX 
    TControlClass = class of TControl; 

var 
    ctx: TRttiContext; 
    t: TRttiInstanceType; 
    inst: TControl; 
begin 
    t := ctx.FindType(Edit1.Text) as TRttiInstanceType; 
    if t = nil then Exit; 
    if not t.MetaclassType.InheritsFrom(TControl) then Exit; 
    inst := TControlClass(t.MetaclassType).Create(Form4); 
    inst.Parent := ...; 
    //... 
end;