アプリケーションをしばらく使用しないで閉じる

Question

私はvb.netでアプリケーションを開発しています。ユーザーがメインフォームにいるのかどうかを知りたいのですが、何もしません。 ユーザーがアプリケーションを使用しているかどうかをチェックし、そうでない場合はログアウトする方法はありますか？

私はいくつかの検索をしましたが、私はこのコードを開発できれば結論は得られませんでした...だから私はこれをどのように解決すべきか考えていますか？

Answer 1

更新を監視し、必要に応じて実行を終了するタイマーでクラスを作成できます。

Public Class IdleWatcher 
    ' TODO: Implements IDisposable 
    ' TODO: and dispose _timer 
    Private _timer As System.Threading.Timer 
    Private _enabled As Boolean 
    Private _lastEvent As DateTime 
    Public Sub New() 
     _timer = New System.Threading.Timer(AddressOf watch) 
     _enabled = False 
     Timeout = 0 
    End Sub 
    Public Event Idle(sender As Object) 
    Public Property Timeout As Long 
    Public Property Enabled As Boolean 
     Get 
      Return _enabled 
     End Get 
     Set(value As Boolean) 
      If value Then 
       _lastEvent = DateTime.Now 
       _timer.Change(0, 1000) 
      Else 
       _timer.Change(System.Threading.Timeout.Infinite, System.Threading.Timeout.Infinite) 
      End If 
     End Set 
    End Property 
    Private Sub watch() 
     If DateTime.Now.Subtract(_lastEvent).TotalMilliseconds > Timeout Then 
      Enabled = false 
      ' raise an event so the form can handle it and log out 
      RaiseEvent Idle(Me) 
     End If 
    End Sub 
    Public Sub Refresh() 
     _lastEvent = DateTime.Now 
    End Sub 
End Class 

このようなフォームアプリケーションで使用することができます。

Public Class Form1 
    Private WithEvents watcher As New IdleWatcher 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load 
     watcher.Timeout = 5000 ' 5 second timeout 
     watcher.Enabled = True 
    End Sub 
    Private Sub Form1_MouseMove(sender As Object, e As MouseEventArgs) Handles Me.MouseMove 
     watcher.Refresh() 
    End Sub 
    Private Sub watcher_idle(sender As Object) Handles watcher.Idle 
     ' If login.show is modal, then you don't need to call MainForm.Close() 
     ' This will depend on your implementation 
     Login.Show() 
     MainForm.Close() 
    End Sub 
End Class 

これは、少なくともForm1のマウスの動きを監視します。インスタンスを複数のフォーム間で共有して、他のフォームからインスタンスをリフレッシュできるようにする場合は、クラスをシングルトンにすることができます。それは1つのための良い候補者です。

フォームのテキストボックスやボタンなどの他のコントロールのイベントハンドラから、リフレッシュを呼び出すこともできます。

さらに、すべてのコントロールをサブクラス化し、ベースクラスの関連するすべてのUIイベントハンドラでリフレッシュコールを追加できます。これは、あなたがどこにいてもリフレッシュしていれば、多くの作業を節約できます。