Julia配列のすべての要素が等しいかどうか確認してください

Question

配列arrのすべての要素が等しいかどうかをテストするための最短方法はall(arr[1] .== arr)です。これは確かに短いですが、それはちょっと面白くないようです。これを行う組み込み関数はありますか？

==(arr...)の行に何かがあると思われますが、==オペレータは2つの引数しか取れないため、動作しません。私はジュリアがarr[1] == arr[2] == arr[3]のような式をどのように構文解析するのか分かりませんが、任意の数の要素を持つ配列にこれを適合させる方法はありますか？

Answer 1

偉大な質問@tparkerと偉大な答え@コリンボワーズ。両者について考えようとしているうちに、ストレートな古い学校のジュリアンの方法 - for -loopを試してみました。同じ要素の長いベクトルの重要な入力の結果が速かったので、このメモを追加します。また、関数名allequalは言及するのに十分なようです。

allequal_1(x) = all(y->y==x[1],x) 

allequal_2(x) = foldl(==,x) # another way but doesn't short-circuit :(

@inline function allequal_3(x) 
    length(x) < 2 && return true 
    e1 = x[1] 
    i = 2 
    @inbounds for i=2:length(x) 
     x[i] == e1 || return false 
    end 
    return true 
end 

ベンチマーク：だからここ変異体である

julia> using BenchmarkTools 

julia> v = fill(1,10_000_000); # long vector of 1s 

julia> allequal_1(v) 
true 

julia> allequal_2(v) 
true 

julia> allequal_3(v) 
true 

julia> @btime allequal_1($v); 
    9.573 ms (1 allocation: 16 bytes) 

julia> @btime allequal_2($v); 
    10.585 ms (0 allocations: 0 bytes) 

julia> @btime allequal_3($v); 
    6.853 ms (0 allocations: 0 bytes) 

UPDATE：ショート機会があるときに、ベンチマークにもう一つの重要な場合があります。だから、（commmentに要求されるように）：

julia> v[100] = 2 
2 

julia> allequal_1(v),allequal_2(v),allequal_3(v) 
(false, false, false) 

julia> @btime allequal_1($v); 
    108.946 ns (1 allocation: 16 bytes) 

julia> @btime allequal_2($v); 
    10.325 ms (0 allocations: 0 bytes) 

julia> @btime allequal_3($v); 
    68.221 ns (0 allocations: 0 bytes) 

allequal_2運賃ひどく、それがショートしないように、第2のバージョンは。

すべて等しいことは、forのバージョンがベースでallequalになるはずです。

Answer 2

allは適切なソリューションですが、それが短絡行動を（発見されたfalseとすぐ壊れる）を採用しますので、あなたは、述語pおよび反復可能itr方法all(p, itr)をしたいです。だから、：

all(y->y==x[1], x) 

違いを表示するには、次の少しスピードテストを実行できます。

for n = 100000:250000:1100000 
    x = rand(1:2, n); 
    @time all(x .== x[1]); 
    @time all(y->y==x[1], x); 
    println("------------------------") 
end 

時間をコンパイルタイミングであるとして最初の反復を無視します。第二は、（1）（itr用データ生成処理に応じて）最悪で最高のO（N）でOである

0.000177 seconds (22 allocations: 17.266 KiB) 
    0.006155 seconds (976 allocations: 55.062 KiB) 
------------------------ 
    0.000531 seconds (23 allocations: 47.719 KiB) 
    0.000003 seconds (1 allocation: 16 bytes) 
------------------------ 
    0.000872 seconds (23 allocations: 78.219 KiB) 
    0.000001 seconds (1 allocation: 16 bytes) 
------------------------ 
    0.001210 seconds (23 allocations: 108.781 KiB) 
    0.000001 seconds (1 allocation: 16 bytes) 
------------------------ 
    0.001538 seconds (23 allocations: 139.281 KiB) 
    0.000002 seconds (1 allocation: 16 bytes) 

第1の解決策は、かなり明らかにO（N）です。