アクションを使用してコントロールの可視性を判断するにはどうすればよいですか？

Question

私は、コントロールの可視性を制御するアクションを使用しようとしています。フォームが最初のボタンが表示され、チェックボックスがチェックされている実行すると

パスカルファイル

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, ActnList, StdCtrls; 

type 
    TForm1 = class(TForm) 
    Button1: TButton; 
    ActionList1: TActionList; 
    Action1: TAction; 
    CheckBox1: TCheckBox; 
    procedure Action1Update(Sender: TObject); 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.Action1Update(Sender: TObject); 
begin 
    (Sender as TAction).Visible := CheckBox1.Checked; 
end; 

end. 

フォームファイル

object Form1: TForm1 
    object Button1: TButton 
    Left = 8 
    Top = 31 
    Action = Action1 
    end 
    object CheckBox1: TCheckBox 
    Left = 8 
    Top = 8 
    Caption = 'CheckBox1' 
    Checked = True 
    State = cbChecked 
    end 
    object ActionList1: TActionList 
    Left = 128 
    Top = 8 
    object Action1: TAction 
     Caption = 'Action1' 
     OnUpdate = Action1Update 
    end 
    end 
end 

：私のコードは次のようになります。チェックボックスをオフにすると、ボタンが消えます。チェックボックスを再度オンにすると、ボタンが再表示されません。

私はこの理由はTCustomForm.UpdateActionsに次のローカル関数内で見つけることができると思う：

procedure TraverseClients(Container: TWinControl); 
var 
    I: Integer; 
    Control: TControl; 
begin 
    if Container.Showing and not (csDesigning in Container.ComponentState) then 
    for I := 0 to Container.ControlCount - 1 do 
    begin 
     Control := Container.Controls[I]; 
     if (csActionClient in Control.ControlStyle) and Control.Visible then 
      Control.InitiateAction; 
     if (Control is TWinControl) and (TWinControl(Control).ControlCount > 0) then 
     TraverseClients(TWinControl(Control)); 
    end; 
end; 

Control.Visibleのチェックが私の行動は二度と自分自身を更新する機会を得てブロックするように表示されます。

私は問題を正しく診断しましたか？これは設計によるのですか、またはQCレポートを提出する必要がありますか？誰かが回避策を知っていますか？

Answer 1

あなたの診断は正しいです。アクションは、最初にDelphiに導入されて以来、そのように機能しました。

私はそれが設計によるものであると考えています（おそらく、テキストや目に見えないコントロールの視覚的な側面を過剰に更新しないよう最適化しています）が、デザインが良いというわけではありません。

影響を受ける可能性があるその他のものを認識する必要がないので、影響を受けるアクションを直接操作するチェックボックスコードが含まれていると思われる回避策 - つまりOnUpdateイベントあなたのためにしてください。チェックボックスがオンになったら、Action1.Updateに電話するか、問題が解決しない場合はAction1.Visible := Trueに電話してください。

代わりに、行動更新コードをTActionList.OnUpdateイベントに追加することもできます。

Answer 2

関連するコントロールが表示されていない場合、ActionUpdateイベントは呼び出されません。チェックボックス1のクリックイベントでアクション更新を明示的に呼び出すようにしてください。

Answer 3

はい、あなたの診断はRobが既に言って説明した通りです。回避策は、個々のTActionのOnUpdateイベントハンドラを使用するのではなく、TActionListのOnUpdateイベントハンドラを使用することです。

procedure TForm1.ActionList1Update(Action: TBasicAction; var Handled: Boolean); 
begin 
    Handled := True; 
    Action1.Visible := CheckBox1.Checked; 
end; 

あなたはそれ以外の場合はアクションリストのにonUpdateハンドラがどちらかと呼ばれることはありません、仕事にこれをリンクし、アクションと少なくとも一つの可視コントロールが必要です。

アクションとアクションリストが初めて導入されたとき、レイ・コノプカ（Raizeコンポーネント）は実装についての記事をいくつか書いて、それらの使い方について非常に助言しました。以来、私は個々のアクションのOnExecuteを使用するが、ActionListのOnUpdateを使用するというプラクティスを採用しました。また、ハンドラで最初に行うことは、HandledをTrueに設定して、必要以上に呼び出されないようにし、そのハンドラ内でActionのEnabledプロパティを一度変更して、GUIが結果としてちらつくことがないようにすることですそれをオフにしてからオンにします。http://edn.embarcadero.com/article/27058 Rayは自分のサイトで3つの記事を持っていましたが、エンバカデロには1つしかありませんが、「組み合わせた」バージョンである可能性があります（そうではありません）。オリジナルを手元に持っていてください）。