スレッドを一時停止する方法は？

Question

何かを描きたい。 GUIがフリーズするので、私はスレッドを描きたい。しかし時々私は図面を一時停止したい（分）。

サスペンド/レジュームは廃止されていますが、どの機能がそれらを置き換えるかはわかりません。

サスペンドとレジュームは推奨されていません。 SleepとSpinWaitは明らかに不適切です。私はDelphiがそのような基本的なプロパティ/機能を提供していないことに驚いています。

スレッドを一時停止/再開するにはどうすればよいですか？

Answer 1

重要なセクションを介してfPaused/fEventの保護が必要な場合があります。具体的な実装に依存します。

interface 

uses 
    Classes, SyncObjs; 

type 
    TMyThread = class(TThread) 
    private 
    fEvent: TEvent; 
    fPaused: Boolean; 
    procedure SetPaused(const Value: Boolean); 
    protected 
    procedure Execute; override; 
    public 
    constructor Create(const aPaused: Boolean = false); 
    destructor Destroy; override; 

    property Paused: Boolean read fPaused write SetPaused; 
    end; 

implementation 

constructor TMyThread.Create(const aPaused: Boolean = false); 
begin 
    fPaused := aPaused; 
    fEvent := TEvent.Create(nil, true, not fPaused, ''); 
    inherited Create(false); 
end; 

destructor TMyThread.Destroy; 
begin 
    Terminate; 
    fEvent.SetEvent; 
    WaitFor; 
    fEvent.Free; 
    inherited; 
end; 

procedure TMyThread.Execute; 
begin 
    while not Terminated do 
    begin 
    fEvent.WaitFor(INFINITE); 
    // todo: your drawings here 
    end; 
end; 

procedure TMyThread.SetPaused(const Value: Boolean); 
begin 
    if (not Terminated) and (fPaused <> Value) then 
    begin 
    fPaused := Value; 
    if fPaused then 
     fEvent.ResetEvent else 
     fEvent.SetEvent; 
    end; 
end;