VBAでゼロ値が欠損値として読み込まれています

Question

シートをトレースし、ブランク値または0値（または "NaN"）値として戻ってくるセルを強調表示しようとしています。私はこれを行うためにネストされたforループを書いたが、私は奇妙なアイテムを見ている。

値が0の場合、セルは赤に変わります。ただし、マクロを実行すると、if statementの条件をパスするすべてのセルが0になっても黄色で終了します。空白のセルを0にするか、セルが真に空白ではないのですか？私は間違いを犯したのですか、あるいは私はVBAの論理について間違っていますか？ Excelで

'i is for the columns 
For i = 2 To 4 'lastColumn 

    totalCounter = 0 
    outageCounter = 0 
    missingCounter = 0 

    'j is for the rows 
    For j = 6 To lastRow 

     'highlight if production outage 
     If mainSheet.Cells(j, i).Value = 0 Then 
      mainSheet.Cells(j, i).Interior.Color = vbRed 
      outageCounter = outageCounter + 1 
     End If 

     'highlight if comm outage 
     If mainSheet.Cells(j, i).Value = "" Or mainSheet.Cells(j, i).Value = "NaN" Then 
      mainSheet.Cells(j, i).Interior.Color = vbYellow 
      missingCounter = missingCounter + 1 
     End If 

     totalCounter = totalCounter + 1 

    Next j 

    mainSheet.Cells(lastRow + 2, i).Value = missingCounter 
    mainSheet.Cells(lastRow + 3, i).Value = outageCounter 
    mainSheet.Cells(lastRow + 4, i).Value = totalCounter 

Answer 1

空のセルのデフォルト値はゼロであるので、あなたがチェックする必要がゼロのためにチェックする前に、いくつかのコンテンツが実際にあります：

Dim c As Range 

For j = 6 To lastRow 

    Set c = mainSheet.Cells(j, i) 

    'highlight if production outage 
    If Len(c.Value) > 0 And c.Value = 0 Then 
     c.Interior.Color = vbRed 
     outageCounter = outageCounter + 1 
    End If 

    'highlight if comm outage 
    If c.Value = "" Or c.Value = "NaN" Then 
     c.Interior.Color = vbYellow 
     missingCounter = missingCounter + 1 
    End If 

    totalCounter = totalCounter + 1 

Next j 

Answer 2

あなたがTextプロパティを使用して0に対してそれを確認することができますあなたはまた、タイピングやメモリを減らすために、いくつかのWith - End Withを使用することができます

（「生産停止」）と「」または「NaNの」（「COMM停止」）は、アクセス

With mainSheet 
    For i = 2 To 4 'lastColumn 

     totalCounter = 0 
     outageCounter = 0 
     missingCounter = 0 

     'j is for the rows 
     For j = 6 To lastrow 

      With .Cells(j, i) 
       Select Case .Text 
        Case 0 
         'highlight if production outage 
         .Interior.Color = vbRed 
         outageCounter = outageCounter + 1 

        Case "", "NaN" 
         'highlight if comm outage 
         .Interior.Color = vbYellow 
         missingCounter = missingCounter + 1 
       End Select 

       totalCounter = totalCounter + 1 
      End With 
     Next j 

     .Cells(lastrow + 2, i).value = missingCounter 
     .Cells(lastrow + 3, i).value = outageCounter 
     .Cells(lastrow + 4, i).value = totalCounter 
    Next i 
End With