すべての空白値の平均とエラー処理

Question

私は3つの値の平均を計算するループマクロを持っています。まれに、3つの値がすべて空白になることがあるので、平均値が空白になるようにセルを残し、ループの次の繰り返しでマクロを実行する必要があります。

私は以前はエラー処理をしていませんでしたので、それに接する最良の方法は不明です。ここに私のコードは次のとおりです。

Sub sumavg() 
     Dim i As Long, j As Long 
     With Worksheets("datasummary") 
      For i = 1 To .Range("A" & .Rows.Count).End(xlUp).Row Step 5 
       For j = 1 To 6 
        With .Rows(i + 2) 
         .Columns(19 + j).Value = Application.WorksheetFunction.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
        End With 
        With .Rows(i + 3) 
         .Columns(19 + j).Value = Application.WorksheetFunction.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
        End With 
       Next 
      Next 

     End With 
    End Sub 

Answer 1

あなたはApplicationオブジェクトのAverage()関数を呼び出すと、エラーであることに対して、その結果を確認することができます。

Sub sumavg() 
    Dim i As Long, j As Long 
    Dim res As Variant '<--| this will store the result of Application.Average() function 

    With Worksheets("datasummary") 
     For i = 1 To .Range("A" & .Rows.count).End(xlUp).row Step 5 
      For j = 1 To 6 
       With .Rows(i + 2) 
        res = Application.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
        If Not IsError(res) Then .Columns(19 + j).Value = Application.WorksheetFunction.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
       End With 
       With .Rows(i + 3) 
        res = Application.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
        If Not IsError(res) Then .Columns(19 + j).Value = Application.WorksheetFunction.Average(.Columns(j), .Columns(j + 5), .Columns(j + 10)) 
       End With 
      Next 
     Next 

    End With 
End Sub 

Answer 2

あなたがOn Error Resume Nextを試すか、単にあなたが平均化されている値にゼロを追加することができます。

Sub sumavg() 
    Dim i As Long, j As Long 
    With Worksheets("Sheet2") 
     For i = 1 To .Range("A" & .Rows.Count).End(xlUp).Row Step 5 
      For j = 1 To 6 
       With .Rows(i + 2) 
        .Columns(19 + j).Value = WorksheetFunction.Average(.Columns(j) + 0, .Columns(j + 5) + 0, .Columns(j + 10) + 0) 
       End With 
       With .Rows(i + 3) 
        .Columns(19 + j).Value = WorksheetFunction.Average(.Columns(j) + 0, .Columns(j + 5) + 0, .Columns(j + 10) + 0) 
       End With 
      Next 
     Next 

    End With 
End Sub