範囲の割り当てられた値で乗算する

Question

2つの範囲を互いに単純に乗算しようとしていますが、これはactiveXボタンでアクティブになりますが、乗算エラーからエラーobvが、私はそれを正しく編集する方法がわかりません。 おかげ

Private Sub CommandButton1_Click() 
Dim rngData  As Range 
    Dim rngNum  As Range 

    Set rngData = ThisWorkbook.Worksheets("Custom Systems").Range("G16") 
     Set rngNum = ThisWorkbook.Worksheets("Custom Systems").Range("c8") 
    rngData = Evaluate(rngData.Address & "* rngNum") 
End Sub 

Answer 1

あなたの質問への最も簡単な解決策は次のようになります。

With ThisWorkbook.Worksheets("Custom Systems") 
    .Range("G16").Value = .Range("G16").Value * .Range("c8").Value 
End With 

または

With ThisWorkbook.Worksheets("Custom Systems") 
    Set RngData = .Range("G16") 
    Set RngNum = .Range("c8") 
    RngData.Value = RngData.Value * RngNum.Value 
End With 

（.Valueがデフォルトプロパティなので、保存したい場合には省略することができます一部の文字を入力中）

---

RngDataの範囲が単一のセルでない場合、上記の方法は機能しません。そのような状況では、各セルを繰り返し処理します。

Dim oneCell As Range 
With ThisWorkbook.Worksheets("Sheet1") 
    Set rngdata = .Range("G11:G27") 
    Set rngnum = .Range("C6") 

    For Each oneCell In rngdata 
     oneCell.Value = oneCell.Value * rngnum.Value 
    Next 

End With 

また、組み込みの[貼り付け特殊値の乗算]メソッドを使用することもできます。

With ThisWorkbook.Worksheets("Sheet1") 
    Set rngdata = .Range("G11:G27") 
    Set rngnum = .Range("C6") 

    rngnum.Copy 
    rngdata.PasteSpecial Paste:=xlPasteValues, _ 
         Operation:=xlMultiply 

End With 

それとも、そのような状況でEvaluate機能を使用することができますが：個人的に

With ThisWorkbook.Worksheets("Sheet1") 
    Set rngdata = .Range("G11:G27") 
    Set rngnum = .Range("C6") 

    'Note: The ".Value" is required in the next line or it will not work 
    rngdata.Value = Evaluate(rngdata.Address & "*" & rngNum.Address) 
End With 

、私はEvaluate方法を好きではない - 私はそれが他の方法よりも効率が悪いと思います。

Answer 2

With ThisWorkbook.Worksheets("Custom Systems") 
    .[G11:G27] = .[G11:G27*C6] 
End With