XSLT - 日付（YYYY-MM-DD）をユリウス日に変換する

Question

標準日付をユリウス日に変換しようとしています。あなたは正常に日付を変換するために使用した関数またはメソッドがありますか？これはXSLT 2.0用です。 1つの追加の制約は、追加のアドオンパッケージを使用することはできません。まっすぐXSLT 2.0

ありがとうございます。

例：2016年7月5日には、まず、YYYY-MMM-DDは、標準的な日付ではありません2457574.50000

Answer 1

に変換します。任意の日付関数を使用するには、指定された文字列をYYYY-MM-DD形式の有効な日付に変換する必要があります。これを済ませれば、計算はかなり簡単になります。

便宜上、次のスタイルシートは2つのカスタム定義関数を使用します.1つは文字列を適切な日付に変換し、もう1つは実際のユリウス日を計算するものです。

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:my="http://www.example.com/my" 
exclude-result-prefixes="xs my"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:function name="my:reformat-date"> 
    <xsl:param name="datestring"/> 
    <xsl:variable name="y" select="substring($datestring, 1, 4)"/> 
    <xsl:variable name="mmm" select="substring($datestring, 6, 3)"/> 
    <xsl:variable name="d" select="substring($datestring, 10, 2)"/> 
    <xsl:variable name="m" select="format-number(index-of(('JAN', 'FEB', 'MAR', 'APR', 'MAY', 'JUN', 'JUL', 'AUG', 'SEP', 'OCT', 'NOV', 'DEC'), $mmm), '00')"/> 
    <xsl:sequence select="xs:date(concat($y, '-', $m, '-', $d))" /> 
</xsl:function> 

<xsl:function name="my:julian-day-number"> 
    <xsl:param name="date" as="xs:date"/> 
    <xsl:variable name="epoch" select="xs:date('-4714-11-24')"/> 
    <xsl:sequence select="days-from-duration($date - $epoch)"/> 
</xsl:function> 

<xsl:template match="/"> 
    <result> 
     <xsl:value-of select="my:julian-day-number(my:reformat-date('2016-JUL-05'))" /> 
    </result> 
</xsl:template> 

</xsl:stylesheet> 

結果

<?xml version="1.0" encoding="UTF-8"?> 
<result>2457575</result> 

---

注：

厳密に言えば、ユリウス日NU正午に変更されます。あなたの入力が日の時刻を示さない場合、指定された日付のAMまたはPM部分の番号を選択するかどうかの決定は純粋に任意です。