Reduce、Map、およびIterations：効率

Question

私はargmaxを実装することを考えています（マップとリダクション）とiterating。ここで

は、マップを使用して、私の実装だと削減：

to-report argmax1 [arguments f] 
    if length arguments = 0 [ show "incorrect length of arguments" report nobody] 
    report first reduce [ ifelse-value ((last ?1) > (last ?2)) [?1] [?2]] map [(list ? (runresult f ?))] arguments 
end 

は、ここで反復を使用して、私の実装です。

to-report argmax2 [arguments f] 
    if length arguments = 0 [ show "incorrect length of arguments" report nobody] 
    let max-argument first arguments 
    let max-evaluation runresult f max-argument 

    foreach arguments 
    [ 
    let current-evaluation runresult f ? 
    if current-evaluation > max-evaluation 
    [ 
     set max-argument ? 
     set max-evaluation current-evaluation 
    ] 
    ] 
    report max-argument 
end 

私の質問は：組み込み関数を使用することによるメリットはありますか？私のmap/reduceコードでは、map/reduceを使用しないときに、一度反復処理を行うのに比べてリストを2回反復処理します。 Pythonでは、map/reduceはPythonバイトコードではなくCにコンパイルされるので、スピードアップになります。 netlogoに相当するものはありますか？

思考？

Answer 1

あなたはmapを取り除くことができます：

to-report argmax [#args #f] 
    let _x0 first #args 
    let _best (list _x0 (runresult #f _x0)) 
    set _best reduce 
    [update ?1 ?2 #f] 
    fput _best butfirst #args 
    report first _best 
end 

to-report update [#xf #x #f] 
    let _f0 last #xf 
    let _f1 (runresult #f #x) 
    report ifelse-value (_f1 > _f0) [list #x _f1] [#xf] 
end 

to test ;to illustrate 
    let _xs n-values 10 [?] 
    show argmax _xs task [(- ?) * ?] 
end