最も長いフィールド長のXSL埋め込み

Question

私はそれにfor-eachループを持つXSLファイルを持っています。そして、私はEXSLTプロセッサを使っていくつかの追加機能（すなわち文字列埋め込み）を行っています。

私ができることをしたいのは、すべてのフィールドを埋めて、そのフィールドの最長レコードの長さにすることです。たとえば、それぞれの名前が最長の名前と同じ長さになるようにしてから、最長のレコード番号の長さになるように各レコード番号を埋め込みます。

私はこれを大丈夫と説明しました。

ありがとうございます。

Answer 1

<xsl:variable name="maxLength"> 
    <xsl:for-each select="name"> 
    <xsl:sort select="string-length(.)" data-type="number" /> 
    <xsl:if test="postion() = last()"> 
     <xsl:value-of select="string-length(.)" /> 
    </xsl:if> 
    </xsl:for-each> 
</xsl:variable> 

Answer 2

C＃を使用すると、Saxon 9やXQSharpなどのXSLT 2.0プロセッサーに移動し、アイテムの最大長を簡単に見つけ出し、http://www.xsltfunctions.com/xsl/functx_pad-string-to-length.htmlなどの関数を使用して埋め込むことができます。 XSLT 1.0とEXSLTを使用する場合は、http://www.exslt.org/math/functions/max/index.htmlを使用して最大値を見つけ、http://www.dpawson.co.uk/xsl/sect2/padding.htmlのソリューションを使用してパッドします。ちょうど楽しみのため

Answer 3

、このスタイルシート：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:variable name="vMaxLengthIds"> 
     <xsl:for-each select="/table/tr[1]/*"> 
      <xsl:variable name="vPosition" select="position()"/> 
      <xsl:for-each select="/table/tr/*[$vPosition]"> 
       <xsl:sort select="string-length(.)" data-type="number" /> 
       <xsl:if test="position() = last()"> 
        <xsl:value-of select="concat('|',generate-id(),'|')" /> 
       </xsl:if> 
      </xsl:for-each> 
     </xsl:for-each> 
    </xsl:variable> 
    <xsl:variable name="vMaxLength" 
        select="/table/tr/*[contains(
             $vMaxLengthIds, 
             concat('|',generate-id(),'|'))]"/> 
    <xsl:variable name="vPaddingMask" 
        select="'            '"/> 
    <xsl:template match="tr"> 
     <xsl:apply-templates/> 
     <xsl:text>&#xA;</xsl:text> 
    </xsl:template> 
    <xsl:template match="td"> 
     <xsl:apply-templates/> 
     <xsl:text> | </xsl:text> 
    </xsl:template> 
    <xsl:template match="th"> 
     <xsl:apply-templates/> 
     <xsl:text> + </xsl:text> 
    </xsl:template> 
    <xsl:template match="tr/*/text()"> 
     <xsl:variable name="vPosition" 
         select="count(../preceding-sibling::*)"/> 
     <xsl:value-of 
      select="concat(
         ., 
         substring(
          $vPaddingMask, 
          1, 
          string-length(
           $vMaxLength[count(preceding-sibling::*) 
              = $vPosition]) 
          - string-length()))"/> 
    </xsl:template> 
</xsl:stylesheet> 

この入力の場合：

<table> 
    <tr> 
     <th>Day</th> 
     <th>Month</th> 
     <th>Year</th> 
    </tr> 
    <tr> 
     <td>1</td> 
     <td>January</td> 
     <td>2011</td> 
    </tr> 
    <tr> 
     <td>31</td> 
     <td>June</td> 
     <td>2011</td> 
    </tr> 
    <tr> 
     <td>11</td> 
     <td>February</td> 
     <td>2011</td> 
    </tr> 
</table> 

出力：

Day + Month + Year + 
1 | January | 2011 | 
31 | June  | 2011 | 
11 | February | 2011 |