Elmポートからユニオンタイプを渡すには？

Question

私はElmを試している間に問題にぶつかりました。私はポートを介して共用体型を渡したいが、私はこのエラーを取得：

Port `setStorage` is trying to communicate an unsupported type. 

34| port setStorage : Model -> Cmd msg 
    ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ 
The specific unsupported type is: 

    Todo.Importance 

The types of values that can flow through in and out of Elm include: 

    Ints, Floats, Bools, Strings, Maybes, Lists, Arrays, 
    Tuples, Json.Values, and concrete records. 

次のように私は藤堂exampleを変更した：

type alias Task = 
    { description : String 
    , completed : Bool 
    , editing : Bool 
    , id : Int 
    , importance : Importance 
    } 

type Importance 
    = Normal 
    | High 
    | Low 

このissueはかなり古いように見えます。あるコメント提供者は、「Json.Valuesをポート経由で渡し、Json.Decode/Encodeする」ことを提案しますが、それを正確に行う方法は？ドキュメントは少し不明で、完全な例はありません。どんな助けもありがたい。

Answer 1

私は、Json.Decoder/Encoderでworkとしました。結局のところ、1つのユニオンタイプを渡すだけのすべてのフィールドをシリアライズする必要がありましたが、それは非常に負担です。

デコーダ：

modelDecoder : Json.Decoder Model 
modelDecoder = 
    Json.object4 Model 
    ("tasks" := Json.list taskDecoder) 
    ("field" := Json.string) 
    ("uid" := Json.int) 
    ("visibility" := Json.string) 

taskDecoder : Json.Decoder Task 
taskDecoder = 
    Json.object5 Task 
    ("description" := Json.string) 
    ("completed" := Json.bool) 
    ("editing" := Json.bool) 
    ("id" := Json.int) 
    ("importance" := Json.string `andThen` importanceDecoder) 

importanceDecoder : String -> Json.Decoder Importance 
importanceDecoder tag = 
    case tag of 
    "Normal" -> Json.succeed Normal 
    "High" -> Json.succeed High 
    "Low" -> Json.succeed Low 
    _ -> Json.fail (tag ++ " is not a recognized tag for Importance") 

そして、エンコーダは：

modelToValue : Model -> Json.Encode.Value 
modelToValue model = 
    Json.Encode.object 
    [ 
     ("tasks", Json.Encode.list (List.map taskToValue model.tasks)), 
     ("field", Json.Encode.string model.field), 
     ("uid", Json.Encode.int model.uid), 
     ("visibility", Json.Encode.string model.visibility) 
    ] 

taskToValue : Task -> Json.Encode.Value 
taskToValue task = 
    Json.Encode.object 
    [ 
     ("description", Json.Encode.string task.description), 
     ("completed", Json.Encode.bool task.completed), 
     ("editing", Json.Encode.bool task.editing), 
     ("id", Json.Encode.int task.id), 
     ("importance", importanceToValue task.importance) 
    ] 

importanceToValue : Importance -> Json.Encode.Value 
importanceToValue importance = 
    case importance of 
    Normal -> Json.Encode.string "Normal" 
    High -> Json.Encode.string "High" 
    Low -> Json.Encode.string "Low" 

Answer 2

JSはそのようなことを知らないので、何よりもユニオンタイプを渡すことはできません。だから、あなたは文字列を渡して、javascriptでcase文を実行するかもしれません - 私はいつもそれを行います。