文法を使って入れ子になっている可能性のある項目を解析する

Question

BibTeXパーサーを書き始めました。私がしたい最初のことは、括弧内の項目を解析することです。ブレースされたアイテムは、著者フィールドまたはタイトルなどです。フィールド内にネストされた中カッコがある可能性があります。次のコードは、は、ネストされた括弧を扱うしません：

use v6; 

my $str = q:to/END/; 
    author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.}, 
    END 

$str .= chomp; 

grammar ExtractBraced { 
    rule TOP { 
     'author=' <braced-item> .* 
    } 
    rule braced-item  { '{' <-[}]>* '}' } 
} 

ExtractBraced.parse($str).say; 

出力：

｢author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.},｣ 
braced-item => ｢{Belayneh, M. and Geiger, S. and Matth{\"{a}｣ 

さて、パーサは、ネストされた括弧を受け入れるようにするために、私はのカウンタを維持したいと思います現在解析されている中括弧の数。閉じ中括弧に遭遇したときに、カウンタを減らします。カウンタがゼロになると、完全な項目を解析したものとみなします。

この考え方に従うために、braced-item正規表現を分割して、各文字に文法アクションを実装しようとしました。 （以下braced-item-char正規表現上のアクションメソッドは、ブレースカウンターを処理する必要があります）：

grammar ExtractBraced { 
    rule TOP { 
     'author=' <braced-item> .* 
    } 
    rule braced-item  { '{' <braced-item-char>* '}' } 
    rule braced-item-char { <-[}]> } 
} 

しかし、突然、今構文解析が失敗しました。おそらく愚かな間違いですが、今はなぜ失敗するのか分かりません。

Answer 1

あなたは結果のデータは、私がこのような何かを見て、それを変更します見てみたい方法を知らず：

my $str = ｢author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.},｣; 

grammar ExtractBraced { 
    token TOP { 
     'author=' 
     $<author> = <.braced-item> 
     .* 
    } 
    token braced-item { 
     '{' ~ '}' 

      [ 
      || <- [{}] >+ 
      || <.before '{'> <.braced-item> 
      ]* 
    } 
} 

ExtractBraced.parse($str).say; 

｢author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.},｣ 
author => ｢{Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.}｣ 

あなたはもう少し構造は、それが少し見えるかもしれませんしたい場合

my $str = ｢author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.},｣; 

grammar ExtractBraced { 
    token TOP { 
     'author=' 
     $<author> = <.braced-item> 
     .* 
    } 
    token braced-part { 
     || <- [{}] >+ 
     || <.before '{'> <braced-item> 
    } 
    token braced-item { 
     '{' ~ '}' 
      <braced-part>* 
    } 
} 

class Print { 
    method TOP ($/){ 
     make $<author>.made 
    } 
    method braced-part ($/){ 
     make $<braced-item>.?made // ~$/ 
    } 
    method braced-item ($/){ 
     make [~] @<braced-part>».made 
    } 
} 


my $r = ExtractBraced.parse($str, :actions(Print)); 
say $r; 
put(); 
say $r.made; 

｢author={Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.},｣ 
author => ｢{Belayneh, M. and Geiger, S. and Matth{\"{a}}i, S.K.}｣ 
    braced-part => ｢Belayneh, M. and Geiger, S. and Matth｣ 
    braced-part => ｢{\"{a}}｣ 
    braced-item => ｢{\"{a}}｣ 
    braced-part => ｢\"｣ 
    braced-part => ｢{a}｣ 
    braced-item => ｢{a}｣ 
     braced-part => ｢a｣ 
    braced-part => ｢i, S.K.｣ 

Belayneh, M. and Geiger, S. and Matth\"ai, S.K. 

：このような、より10

<-[{}]>+の+が最適化され、<before '{'>となり、両方とも省略でき、それでも機能します。