Delphiを使用してすべてのファイルとフォルダを再帰的に削除

Question

フォルダとそのすべてのサブフォルダを再帰的に削除しようとしていますが、全く機能していないため、コードをチェックして、 ？

私は、Windows XPの下でD7を通じて

if FindFirst (FolderPath + '\*', faAnyFile, f) = 0 then 
     try    
     repeat 

      if (f.Attr and faDirectory) <> 0 then 
       begin 
        if (f.Name <> '.') and (f.Name <> '..') then 
         begin        
         RemoveDir(FolderPath +'\'+ f.Name); 
         end 
        else 
         begin 
         //Call function recursively... 
         ClearFolder(FolderPath +'\'+ f.Name, mask, recursive); 
         end; 
       end; 

     until (FindNext (f) <> 0); 
     finally 
     SysUtils.FindClose (f) 
     end; 
end; 

Answer 1

をこのコードを実行しているのではなく、すべてこれは、ハードを自分で働いています、私はちょうどSHFileOperationを使用したい：

uses 
    ShellAPI; 

procedure DeleteDirectory(const DirName: string); 
var 
    FileOp: TSHFileOpStruct; 
begin 
    FillChar(FileOp, SizeOf(FileOp), 0); 
    FileOp.wFunc := FO_DELETE; 
    FileOp.pFrom := PChar(DirName+#0);//double zero-terminated 
    FileOp.fFlags := FOF_SILENT or FOF_NOERRORUI or FOF_NOCONFIRMATION; 
    SHFileOperation(FileOp); 
end; 

それは価値があるものについては、あなたのコードの問題は、DeleteFileを呼び出すことはありません。ディレクトリが空になることはありません。RemoveDirへの呼び出しは失敗します。あなたのコードでのエラーチェックの欠如は本当に助けにはなりませんが、ファイルを削除するコードを追加すると、そのコードは半分の形になります。あなたはまた、再帰を気にする必要があります。すべての子が最初に削除され、次に親コンテナが削除されることを確認する必要があります。それは正しいものになるにはある程度のスキルが必要です。基本的なアプローチは、このようなものです：

procedure DeleteDirectory(const Name: string); 
var 
    F: TSearchRec; 
begin 
    if FindFirst(Name + '\*', faAnyFile, F) = 0 then begin 
    try 
     repeat 
     if (F.Attr and faDirectory <> 0) then begin 
      if (F.Name <> '.') and (F.Name <> '..') then begin 
      DeleteDirectory(Name + '\' + F.Name); 
      end; 
     end else begin 
      DeleteFile(Name + '\' + F.Name); 
     end; 
     until FindNext(F) <> 0; 
    finally 
     FindClose(F); 
    end; 
    RemoveDir(Name); 
    end; 
end; 

私は明瞭にするためにエラーチェックを省略しましたが、あなたはDeleteFileとRemoveDirの戻り値をチェックする必要があります。

Answer 2

procedure DeleteDir(const DirName: string); 
var 
    Path: string; 
    F: TSearchRec; 

begin 
    Path:= DirName + '\*.*'; 
    if FindFirst(Path, faAnyFile, F) = 0 then begin 
    try 
     repeat 
     if (F.Attr and faDirectory <> 0) then begin 
      if (F.Name <> '.') and (F.Name <> '..') then begin 
      DeleteDir(DirName + '\' + F.Name); 
      end; 
     end 
     else 
      DeleteFile(DirName + '\' + F.Name); 
     until FindNext(F) <> 0; 
    finally 
     FindClose(F); 
    end; 
    end; 
    RemoveDir(DirName); 
end;