Scanf ARMアセンブリを使用したセグメンテーションフォールト

Question

私はアセンブリに新しく、過去数日間はインターネットを掃除して助けを得ましたが、役に立たなかった。

.data 

format: .asciz "%s" 
string: .asciz "Output: %s\n" 

prompt: .asciz ">" 

.text 
.global main 
.main: 

    ldr r0, addr_prompt  /*loading address of prompt message in r0*/ 
    bl printf    /*calling printf*/ 

    ldr r0, addr_format  /*loading first parameter of scanf*/ 
    ldr r1, addr_string  /*loading second parameter of scanf*/ 
    bl scanf    /*calling scanf*/ 

    /*below I am trying to print out the user 
    input from scanf*/ 

    ldr r1, [r1]    
    bl printf 

    mov r7, #1 
    swi 0 

addr_prompt: .word prompt 
addr_format: .word format 
addr_string: .word string 

実行すると、「セグメンテーションフォールト」エラーが発生します。誰かが私に間違ったことを知らせてもらえますか？どんな助けでも大歓迎です。

編集：提案固定コピーエラーとしてコードに追加コメント（scanfの - > BLのscanf）

Answer 1

バッファ/記憶は、入力データを格納するために必要とされます。ラズベリーパイRaspbianから

.data 

format: .asciz "%s" 

string: .asciz "Output: %s\n" 
prompt: .asciz ">" 

storage: .space 80   @ --- added buffer 

.text 
.global main 
main:      @ --- removed . 

    ldr r0, addr_prompt  /*loading address of prompt message in r0*/ 
    bl printf    /*calling printf*/ 

    ldr r0, addr_format  /*loading first parameter of scanf*/ 
    ldr r1, addr_storage @ --- location to write data from input 
    bl scanf    /*calling scanf*/ 

    /*below I am trying to print out the user 
    input from scanf*/ 

    ldr r1, addr_storage @ --- data location 
    ldr r0, addr_string  @ --- printf format 
    bl printf 

    mov r0, #0    @ --- good return code 
    mov r7, #1 
    swi 0 

addr_prompt: .word prompt 
addr_format: .word format 
addr_string: .word string 
addr_storage: .word storage @ --- address of buffer 

出力：

as -o printf10.o printf10.s 
gcc -o printf10 printf10.o 

./printf10; echo $? 
>Hello 
Output: Hello 
0