バッチファイルを使用してコマンドプロンプトを複製する

Question

バッチファイルを使用してコマンドプロンプトを複製しようとしています。私の現在のコードは以下の通りです。

@echo off 
title Command Prompt 
:LOOP 
set /p COMMAND="%CD%>" 
title Command Prompt - %COMMAND% 
call %COMMAND% 
echo. 
title Command Prompt 
goto LOOP 

しかし、私には1つの問題があります。私がプログラムを呼び出す場合（gpedit.mscなど）、バッチファイルは、プログラムの復帰を待つことなく、通常のコマンドプロンプトが返ってくるまで、プログラムが戻るまで待機します。

コマンドがプログラムであるかどうかをテストして、startコマンドを使用する方法を教えてください。

Answer 1

user32.dllの実行ファイルを検索することができます。

@echo off 
title Command Prompt 
:LOOP 
    set /p COMMAND="%CD%>" 
    title Command Prompt - %COMMAND% 

    call :is_gui %COMMAND% 
    if errorlevel 1 (
     call %COMMAND% 
    ) else (
     start "" %COMMAND% 
    ) 

    echo. 
    title Command Prompt 
    goto LOOP 

:is_gui app_name 
    set app_name=%~1 
    set file_app= 

    rem Get path of application 
    if exist "%app_name%" (
     set file_app=%app_name% 
    ) else (
     rem Lookup path of app 
     for %%P in (%PATHEXT%) do (
      for %%I in (%1 %1%%P) do (
      if exist "%%~$PATH:I" (
       set file_app=%%~$PATH:I 
       goto continue 
      ) 
     ) 
     ) 
    ) 
    :continue 
    if "%file_app%"=="" exit /b 1 
    find /i "user32.dll" < "%file_app%" >nul 2>&1 
    exit /b %errorlevel%