VBAでデータ構造を設定

Question

Excel VBAで使用するsetデータ構造を探しています。私が今までに見つけたのは、mapと思われるScripting.Dictionaryです。

VBAにも同様の設定がありますか？

基本的には、特定の値が既に追加されているかどうかを調べるのに有効なデータ構造を探しています。

Answer 1

あなたは、コレクションを使用して、次の機能を行うことができ、コレクションが一意のキー識別子を強制：

Public Function InCollection(Col As Collection, key As String) As Boolean 
    Dim var As Variant 
    Dim errNumber As Long 

    InCollection = False 
    Set var = Nothing 

    Err.clear 
    On Error Resume Next 
    var = Col.Item(key) 
    errNumber = CLng(Err.Number) 
    On Error GoTo 0 

    '5 is not in, 0 and 438 represent incollection 
    If errNumber = 5 Then ' it is 5 if not in collection 
    InCollection = False 
    Else 
    InCollection = True 
    End If 

End Function 

Answer 2

は.NET ArrayListを見てみましょう、それはAdd、Contains、Sortなどのような方法を持っているあなたは、インスタンス化することができますVBSやVBA環境内のオブジェクト：

Set ArrayList = CreateObject("System.Collections.ArrayList") 

Scripting.Dictionaryもニーズに合わせて、それが一意キーを持っている、Exists方法すべてキーがすでに辞書に入っているかどうかを確認します。

しかし、ADODB経由のSQLリクエストは、おそらくこのケースではより効率的です。以下の例は、ワークシートにSQLクエリを経由してユニークな行を取得する方法を示しています。

Option Explicit 

Sub GetDistinctRecords() 

    Dim strConnection As String 
    Dim strQuery As String 
    Dim objConnection As Object 
    Dim objRecordSet As Object 

    Select Case LCase(Mid(ThisWorkbook.Name, InStrRev(ThisWorkbook.Name, "."))) 
     Case ".xls" 
      strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;User ID=Admin;Data Source='" & ThisWorkbook.FullName & "';Mode=Read;Extended Properties=""Excel 8.0;HDR=YES;"";" 
     Case ".xlsm", ".xlsb" 
      strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source='" & ThisWorkbook.FullName & "';Mode=Read;Extended Properties=""Excel 12.0 Macro;HDR=YES;"";" 
    End Select 

    strQuery = "SELECT DISTINCT * FROM [Sheet1$]" 
    Set objConnection = CreateObject("ADODB.Connection") 
    objConnection.Open strConnection 
    Set objRecordSet = objConnection.Execute(strQuery) 
    RecordSetToWorksheet Sheets(2), objRecordSet 
    objConnection.Close 

End Sub 

Sub RecordSetToWorksheet(objSheet As Worksheet, objRecordSet As Object) 

    Dim i As Long 

    With objSheet 
     .Cells.Delete 
     For i = 1 To objRecordSet.Fields.Count 
      .Cells(1, i).Value = objRecordSet.Fields(i - 1).Name 
     Next 
     .Cells(2, 1).CopyFromRecordset objRecordSet 
     .Cells.Columns.AutoFit 
    End With 

End Sub 

ソース・データがSheet1に配置する必要があり、その結果はSheet2に出力されます。その方法の唯一の制限は、ADODBがドライブのExcelブックに接続するため、実際の結果を得るためにクエリの前に変更を保存する必要があることです。

あなたは非明確な行のセットのみを取得したい場合は、次のようにクエリをする必要があります（あくまで一例、クエリにフィールドのあなたのセットを配置する必要があります）：

strQuery = "SELECT CustomerID, CustomerName, ContactName, Address, City, PostalCode, Country FROM [Sheet1$] GROUP BY CustomerID, CustomerName, ContactName, Address, City, PostalCode, Country HAVING Count(*) > 1" 

Answer 3

単にセット様の操作だけを公開するScripting.Dictionaryのラッパーを記述します。

clsSet

Option Explicit 

Private d As Scripting.Dictionary 

Private Sub Class_Initialize() 
    Set d = New Scripting.Dictionary 
End Sub 

Public Sub Add(var As Variant) 
    d.Add var, 0 
End Sub 

Public Function Exists(var As Variant) As Boolean 
    Exists = d.Exists(var) 
End Function 

Public Sub Remove(var As Variant) 
    d.Remove var 
End Sub 

そして、あなたはそうのようにそれを使用することができます：予想通り、真偽とFalse出力し

mdlMain

Public Sub Main() 
    Dim s As clsSet 
    Set s = New clsSet 

    Dim obj As Object 

    s.Add "A" 
    s.Add 3 
    s.Add #1/19/2017# 

    Debug.Print s.Exists("A") 
    Debug.Print s.Exists("B") 
    s.Remove #1/19/2017# 
    Debug.Print s.Exists(#1/19/2017#) 
End Sub 

。