作業ディレクトリからの相対パスを取得する方法は？

Question

私は、作業ディレクトリとサブディレクトリにあるすべてのファイル.txtを再帰的にループし、そのファイルで何かを実行するスクリプトを持っています。今私はexclude.txtファイルにリストされている特定のサブディレクトリ内のすべてのファイルを除外したいと思います：

@ECHO OFF 
SETLOCAL EnableDelayedExpansion 

for /r %%f in (*.txt) do (
    CALL:processFile %%f %%~df%%~pf 
) 
GOTO:EOF 

:processFile 
    SET file_=%~1 
    SET path_=%~2     <- %%~df%%~pf is the full path :(
    find "!path_!" exclude.txt 
    IF !ERRORLEVEL! EQU 1 (
     REM do something here 
    ) 
    GOTO:EOF 

しかし、%%/~df%%~pfは絶対パスに展開されます。 作業ディレクトリからの相対パスはどのように取得できますか？サブディレクトリのみをexclude.txtに、完全なパスは表示しません。

PS：私はもちろん、exclude.txtからの相対パスを読ん%cd%を追加し、いくつかのexclude.tempに書き込み、その後、この一時ファイルで検索、私はよりよい方法があると思いますができます。

Answer 1

これを試してください。ここ

@ECHO OFF 
SETLOCAL EnableDelayedExpansion 

for /r %%F in (*.txt) do (
    echo %%F|findstr /I /G:exclude.txt >nul 2>&1 
    IF NOT "!ERRORLEVEL!"=="0" (
     REM do something here 
    ) 
) 

Answer 2

xcopyは相対パスを返すことが可能であるという事実に依存する、異なるアプローチです。何もコピーしたくないので、/Lスイッチを使用する必要があります（リストしますがコピーはしません）。

for /F "delims=" %%F in (' 
    xcopy /L /I /S ".\*.txt" "%TEMP%" ^| find ".\" 
') do (
    echo(Relative path to file: "%%~F" 

    rem // This block is only needed in case the leading `.\` disturbs: 
    set "FILE=%%~F" 
    setlocal EnableDelayedExpansion 
    echo(Relative path, no `.\`: "!FILE:*.\=!" 
    endlocal 
)