Try :: Tinyのfinallyブロックから値を返しても、なぜ「初期化されていない値の使用」警告が表示されるのですか？

Question

コードの一部は、以下の私にエラーを与える理由は私には不明である：

Use of uninitialized value in addition (+) at combined_op_test.pl line 12.

私は$success_countの値は、各繰り返しで、サブルーチンから返された値ずつ増加することを期待。

#!/usr/bin/env perl 
use strict; 
use warnings; 

use 5.014; 
use Try::Tiny; 

my $success_count = 0; 

for (1..10) { 
    $success_count += error_causing_sub(); 
} 

sub error_causing_sub { 
    try { 
     die ("Error."); 
    } catch { 
    } finally { 
     if (@_) { 
      say "Error occured."; 
      return 0; 
     } 
     else { 
      say "Error did not occur."; 
      return 1; 
     } 
    }; 
} 

すべてのヘルプは高く評価されています。ここでは

はコードです。

Answer 1

としては、文書のCAVEATSセクションで説明した、returnサブから戻らない、それはfinallyから復帰：

return returns from the try block, not from the parent sub (note that this is also how eval works, but not how TryCatch works):

sub parent_sub { 
    try { 
    die; 
    } 
    catch { 
    return; 
    }; 
    say "this text WILL be displayed, even though an exception is thrown"; 
} 

@simbabque notes

として、finallyの戻り値は無視されます。 tryが失敗した場合は、catchの戻り値は関連している、そしてそれは空です：

The return value of the catch block is not ignored, so if testing the result of the expression for truth on success, be sure to return a false value from the catch block: ...

次のコードは、私にはより論理的になります。

#!/usr/bin/env perl 
use strict; 
use warnings; 

use 5.014; 
use Try::Tiny; 

my $success_count = 0; 

for (1..10) { 
    $success_count += error_causing_sub(); 
} 

say $success_count; 

sub error_causing_sub { 
    my $ret; 
    try { 
     die ("Error.") if rand(1) < 0.5; 
     say "Error did not occur."; 
     $ret = 1; 
    } catch { 
     say "Error occured."; 
     $ret = 0; 
    }; 

    return $ret; 
} 

また、私の知る限り、the issues with eval that made Try::Tiny relevant were fixed in 5.14。だから、それを使うだけで良いかもしれません。

#!/usr/bin/env perl 
use strict; 
use warnings; 

use 5.014; 

my $success_count = 0; 

$success_count += error_causing_sub() for 1 .. 10; 

say $success_count; 

sub error_causing_sub { 
    my $ret; 
    eval { 
     die ("Error.") if rand(1) < 0.5; 
     say "Error did not occur."; 
     $ret = 1; 
    } or do { 
     say "Error occured."; 
     $ret = 0; 
    }; 

    return $ret; 
}