起動時にVBAからマクロセキュリティを開く

Question

「VBAプロジェクトオブジェクトモデルへのアクセスを信頼する」オプションが有効になっているかどうかを起動時にチェックするコードがあります。

有効になっていない場合、ユーザーに簡単にアクセスできるようにマクロセキュリティ設定を開くためのプログラムが必要です。

ほとんどの場合、これを行うコードを作成しましたが、回避方法がわからないという問題が発生しました。次のように

コードは次のとおりです。

Private Sub Workbook_Open 
If Not VBATrusted() Then 
    MsgBox "Trust access to the VBA project object model is not enabled" & vbNewLine & vbNewLine & _ 
    "Please allow access by ticking the checkbox in the window that appears after clicking Ok" 
    Application.CommandBars.ExecuteMso ("MacroSecurity") 
End If 
End Sub 

Function VBATrusted() As Boolean 
    On Error Resume Next 
    VBATrusted = (Application.VBE.VBProjects.Count) > 0 
End Function 

このコードは、その仕事をして、マクロ設定がデフォルトにしない限り、私はマクロをアクティブにしてからランを取得した場合には、「通知にすべてのマクロを無効にします」 -2147467259（80004005）オブジェクト '_CommandBars'の 'ExecuteMso'メソッドが失敗しました。

このエラーは最初の起動時に発生します。連続した起動時にマクロをアクティブにする必要はないため、ファイルの場所。

私は2秒間マクロを一時停止しようとしましたが、それは私のために何もしなかったし、エラーを捕らえて再びApplication.CommandBars.ExecuteMso ("MacroSecurity")行を実行しようとしたエラーハンドラもありませんでした。それは同じエラーで終わった。

エラーがApplication.CommandBars.ExecuteMso ("MacroSecurity")行にあるとデバッガから通知されますが、そのエラーメッセージではあまり驚くことではありません。

Answer 1

上記のコメントで@CLRによって提案されたような単純な解決策しかし、最初にテストしたときにはうまくいかなかった（ユーザーエラー！）。

Option Explicit 

Private Sub Workbook_Open() 
If Not VBATrusted() Then 
    MsgBox "Trust access to the VBA project object model is not enabled. " & vbNewLine & _ 
    "Please allow access by ticking the checkbox in the window that appears" 
    Application.OnTime Now + TimeValue("00:00:01"), "ThisWorkbook.SetSecurity" 
End If 
End Sub 

Function VBATrusted() As Boolean 
    On Error Resume Next 
    VBATrusted = (Application.VBE.VBProjects.Count) > 0 
End Function 

Sub SetSecurity(Optional foo) 
    Application.CommandBars.ExecuteMso "MacroSecurity" 
End Sub 

もう少し手の込んだ：ユーザーがクリックした後、セキュリティ設定ペインが開きますワークシートにMSForms.CommandButtonを追加し、すべてのコードがThisWorkbookモジュールになります。 MsgBoxにボタンをクリックし、セキュリティ設定を変更するようにユーザーに指示します。

Module1で

、ボタンのClickイベントハンドラ：ThisWorkbookモジュールで

Option Explicit 
Sub Button1_Click() 
    Call ThisWorkbook.SetSecurity 
End Sub 

：

Option Explicit 

Private Sub Workbook_Open() 
If Not VBATrusted() Then 
    MsgBox "Trust access to the VBA project object model is not enabled. " & vbNewLine & _ 
    "Please allow access by:" & vbNewLine & vbNewLine & _ 
    "1. Clicking the button on this sheet" & vbNewLine & _ 
    "2. Ticking the checkbox in the window that appears" 
End If 
End Sub 

Function VBATrusted() As Boolean 
    On Error Resume Next 
    VBATrusted = (Application.VBE.VBProjects.Count) > 0 
End Function 

Sub SetSecurity(Optional foo) 
    Application.CommandBars.ExecuteMso "MacroSecurity" 
End Sub 

Answer 2

ここにボックス外で考えてみましょう...
シートに大きなメッセージを入れて、マクロをアクティブにしてから、自動開始マクロを削除または非表示にするとどうなりますか？それはメッセージを必要とする人に伝えますが、他の人には伝えません。