バッチエコー特定の行

Question

これは私の最初の投稿であり、バッチにはあまり熟練していないので、本当にうんざりするとすみませます。

基本的に、一度実行すると、ユーザーがファイルパスと行番号を入力し、指定されたファイルの指定された行がコマンドラインに出力される小さなバッチスクリプトに取り組んでいます。私はすべての変数とコマンドが動作しているので、テキストファイルの行を指定するコマンドはうまくいきます。変数を入れても機能しません。今、私は私がやっている推測しているが、私はバッチに新たなんだので、明らかに間違っているが、とにかくここに私のコードです：

@echo off  
color b  
:top  
title specified line copy tool  
echo input full path to txt file  
set /P filepath=">"  
cls  
echo what line would you like to copy?  
set /P lineoriginal=">"  
set /A actualline=%lineoriginal%-1 
for /F "skip=%actualline% delims=" %%i in (%filepath%) do if not defined output  set "output=%%i"  
echo %output%  
pause 

あなたは、私が間違って何をしたかの感謝を見ることができます参照してください。このリンクから

Answer 1

Windows Batch file to echo a specific line number

あなたがそのように、この関数を呼び出すことができます。Call:ReadNthLine <File> <nLine>

:ReadNthLine File nLine 
FOR /F %%A IN ('^<"%~1" FIND /C /V ""') DO IF %2 GTR %%A (ECHO Error: No such line %2. 1>&2 & EXIT /b 1) 
FOR /F "tokens=1* delims=]" %%A IN ('^<"%~1" FIND /N /V "" ^| FINDSTR /B /C:"[%2]"') DO ECHO.%%B 
EXIT /b 

そして、あなたのコードは、そのように書き換えることができます。

@echo off 
color b 
:top 
cls 
title specified line copy tool 
echo input full path to txt file 
set /P "filepath=>" 
cls  
echo what line would you like to copy ?  
set /P "nLine=>" 
cls 
CALL :ReadNthLine "%filepath%" %nLine% 
PAUSE >NUL & goto:top 
GOTO :EOF 
::*************************************************************************************** 
:ReadNthLine File nLine 
FOR /F %%A IN ('^<"%~1" FIND /C /V ""') DO IF %2 GTR %%A (ECHO Error: No such line %2. 1>&2 & EXIT /b 1) 
FOR /F "tokens=1* delims=]" %%A IN ('^<"%~1" FIND /N /V "" ^| FINDSTR /B /C:"[%2]"') DO ECHO.%%B 
EXIT /b 
::***************************************************************************************