pandocのバッチコマンドが必要

Question

サブディレクトリのあるディレクトリがあり、docxをhtmlに変換しようとしています。 は、これまでのところ、私は、このコマンドを発見した：

@ECHO off 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 
CALL pandoc -o -s "%filename%".html --self-contained "%filename%".docx 
GOTO selectfile 

問題は、そのファイル名のための私を求めていると私は仕事をするために、すべてのサブフォルダ内のこのbatファイルを配置する必要があります。 サブフォルダを自動的に検出し、すべてのdocxファイルを同じ名前のhtmlファイルに変換するようにいくつかの変更を加えたいと思います。 これは可能ですか？ 誰でもこのスクリプトを変更できますか？ 本当に感謝しています。

次のコメントのコードスニペットは、助けることができる

Answer 1

：

@echo OFF 
SETLOCAL EnableExtensions 

rem iterate all *.docx recursively 
for /f "delims=" %%G in ('dir /B /S *.docx 2^>NUL') do (

    rem check .html existence 
    if not exist "%%~dpnG.html" (

     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 

     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 

     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

編集

私はそれがサブフォルダ 自動的とを検出するようにいくつかの変更をしたいすべての変換docxファイルをhtmlファイル に同じ名前で保存します。

@echo OFF 
SETLOCAL EnableExtensions 
:selectfile 
:: Clear any preexisting filename variables 
SET filename= 
:: Ask which file we're converting. 
SET /p filename=Which file? (Don't include the .docx file extension): 

if not defined filename GOTO selectfile 

rem iterate all %filename%.docx recursively 
for /f "delims=" %%G in ('dir /B /S "%filename%.docx" 2^>NUL') do (
    rem check .html existence 
    if not exist "%%~dpnG.html" (
     rem change the current directory and store the previous path for use by the POPD 
     pushd "%%~dpG" 
     rem `CALL pandoc` is merely displayed for debugging purposes 
     rem    remove ECHO no sooner than debugged   
     ECHO CALL pandoc -o -s "%%~nG.html" --self-contained "%%~nxG" 
     rem change directory back to the path most recently stored by the PUSHD command 
     popd 
    ) 
) 

GOTO selectfile 

資源（必読）：

• （コマンドリファレンス）An A-Z Index of the Windows CMD command line
• （追加の特殊性を次のようにあなたのスクリプトにコードスニペットの上に埋め込むことができ

）Windows CMD Shell Command Line Syntax

（%~Gなど特別ページ）Command Line arguments (Parameters)

（2>NULなど特別ページ）Redirection