複数の一致変数とのマージ

Question

プロジェクトのデータセットの結合が困難です。私たちの主なデータセットは、個々の裁判官によって組織されています。これは属性データセットです。

judge 
    j | x | y | z 
----|----|----|---- 
    1 | 2 | 3 | 4 
    2 | 5 | 6 | 7 

第2のデータセットは、ケースデータベースである。各観察は事例であり、審査員は3つの変数のうちの1つに現れることができる。

case 
case | j1 | j2 | j3 | year 
-----|----|----|----|----- 
    1 | 1 | 2 | 3 | 2002 
    2 | 2 | 3 | 1 | 1997 

我々はjudgeによってマッチング、属性データベースに症例データベースをmergeしたいと思います。したがって、それぞれjudgeがj1、j2、またはj3にある場合、そのケースの観察結果が追加され、以下のようなデータセットが作成されます。

combined 
    j | x | y | z | case | year 
---|----|----|----|-------|-------- 
    1 | 2 | 3 | 4 | 1 | 2002 
    1 | 2 | 3 | 4 | 2 | 1997 
    2 | 5 | 6 | 7 | 1 | 2002 
    2 | 5 | 6 | 7 | 2 | 1997 

私の最高の推測では、私はこれがマージデータセットがj識別に発生する可能性があることを三つの可能な変数を持っている、特に以来、動作することをわからないよ、しかし

rename j1 j 
merge 1:m j using case 
rename j j1 
rename j2 j 
merge 1:m j using case 

を使用することです。

Answer 1

あなたの例ははっきりしていますが、足場を取り除くためにエンジニアリング編集を必要としないようなコードとしても良いでしょう。 SSCのdataex（ssc inst dataex）を参照してください。

これは紛失したreshapeのケースだと思います。

clear 
input j x y z 
    1 2 3 4 
    2 5 6 7 
end 
save judge 

clear 
input case j1 j2 j3 year 
    1 1 2 3 2002 
    2 2 3 1 1997 
end 

reshape long j , i(case) j(which) 

merge m:1 j using judge 

list 

    +-------------------------------------------------------+ 
    | case which j year x y z   _merge | 
    |-------------------------------------------------------| 
    1. | 1  1 1 2002 2 3 4  matched (3) | 
    2. | 2  3 1 1997 2 3 4  matched (3) | 
    3. | 2  1 2 1997 5 6 7  matched (3) | 
    4. | 1  2 2 2002 5 6 7  matched (3) | 
    5. | 2  2 3 1997 . . . master only (1) | 
    |-------------------------------------------------------| 
    6. | 1  3 3 2002 . . . master only (1) | 
    +-------------------------------------------------------+ 

drop if _merge < 3 
list 

    +---------------------------------------------------+ 
    | case which j year x y z  _merge | 
    |---------------------------------------------------| 
    1. | 1  1 1 2002 2 3 4 matched (3) | 
    2. | 2  3 1 1997 2 3 4 matched (3) | 
    3. | 2  1 2 1997 5 6 7 matched (3) | 
    4. | 1  2 2 2002 5 6 7 matched (3) | 
    +---------------------------------------------------+