BOXPLOTPARAM（SAS GTL）でのデータの分離

Question

ボックスとウィスカープロットとしてプロットするデータを要約しました。私は特定のクラスに "外れ値"ポイントを追加しました。 2つの別々のプロットが必要です.1つは外れ値があり、もう1つは外れています。

は、ここで私が持っているものです。これを生産

data test; 
input _stat_ $ _label_ $ col1 has_outlier; 
datalines; 
Max A 2.1837546442 0 
Mean A 0   0 
Median A 0.0101415946 0 
Min A -2.698021137 0 
Q1  A -0.656874482 0 
Q3  A 0.6635898047 0 
Max B 2.2346071965 1 
Mean B 0   1 
Median B -0.025621533 1 
Min B -2.380132327 1 
Q1  B -0.658781626 1 
Q3  B 0.7248025307 1 
Outlier B -2.120639115 1 
Max C 1.9904289904 0 
Mean C 0   0 
Median C 0.0164299847 0 
Min C -2.032578831 0 
Q1  C -0.454702942 0 
Q3  C 0.7259160175 0 
; 



proc template; 
    define statgraph boxplotparm1; 
    begingraph; 
     layout datapanel classvars=(has_outlier)/columns=2 rowdatarange=union; 
      layout prototype/cycleattrs=true; 
      boxplotparm x=_label_ y=col1 stat=_stat_/
      datalabel=datalabel spread=true dataskin=sheen outlierattrs=(color=red symbol=Asterisk);  
      endlayout; 
     endlayout; 
    endgraph; 
    end; 
run; 

/* Generate the plot. */ 
proc sgrender data=test template=boxplotparm1; 
run; 

：

私はボックスプロットが存在しないのチャートからクラスを削除したいと思います。したがって、「外れていない」グループには「A」と「C」のみが表示され、「外れ値」グループには「B」のみが表示されます。

Answer 1

X軸を制御するCOLUMNDATARANGE=UNIONとお望みのものが得られると思います。 UNIONALLはデフォルトであり、すべてのグラフにわたって一貫したX軸を持つように指示します。 UNIONはそうしないように指示します。

あなたがこのルートに行っても、私は疑いの余地のある幅を得るのは難しいでしょう。

proc template; 
    define statgraph boxplotparm1; 
    begingraph; 
     layout datapanel classvars=(has_outlier)/columns=2 rowdatarange=union columndatarange=union; 
      layout prototype/cycleattrs=true; 
      boxplotparm x=_label_ y=col1 stat=_stat_/
      datalabel=datalabel spread=true 
      dataskin=sheen outlierattrs=(color=red symbol=Asterisk) 
      ;  
      endlayout; 
     endlayout; 
    endgraph; 
    end; 
run;