コード名を使用してシートを参照

Question

With Worksheets(Sheet1) '* Error here 
    'my code here 
End With 

マイシートCodeNameはsheet1です。
ここでエラーは型の不一致を示します。

誰かがエラーを削除しますか？

Answer 1

1）インデックスによってシートを参照してください：

With Worksheets(1) 
    '<stuff here> 
End With 

`インデックス」 "ブック内のシートの順序" に依存しています。シートオーダーをシャッフルすると、これ以上同じシートを参照しないことがあります。

2）名前でシートを参照してください：

With Worksheets("Your Sheet Name") 
    '<stuff here> 
End With 

これは、ワークシートの.Name財産であり、Excelワークシート]タブでとVBAプロジェクトエクスプローラで、括弧内に表示名です。

3）コードネームでシートを参照してください：

あなたが実際にワークシートの.CodeNameプロパティを使用していたが示唆されました。上記の2つの例のように角括弧内の参照はできませんが、上記の回答に反して存在します！作成時にシートに自動的に割り当てられ、以前に作成されたCodeNames内の次の未使用の数値が「シート」になります。

CodeNameを使用することの利点は、（Index異なり）シート順序に依存せず、ユーザがExcelでシートの名前を変更することによって簡単にNameを変更した場合、それが変化しないことです。

不都合な点は、コードが複雑であいまいである可能性があることです。 CodeNameは読み取り専用ですので[1]これは改善できませんが、上記の利点を保証します！詳細については、参照先のドキュメントを参照してください。

それを使用しての最初の方法：直接...

With Sheet1 
    '<stuff here> 
End With 

それを使用しての第二の方法：間接的に、より多くの明快さや柔軟性を提供することがあり、ワークシートのCodeNameプロパティを使用する方法を示しています...

シートをループしてCodeNameプロパティを読み取ると、最初に希望のシートのIndexまたはNameプロパティを見つけることができます。次に、これを使用してシートを参照することができます。

Dim sh as WorkSheet 
Dim shName as String 
Dim shIndex as Integer 

' Cycle through all sheets until sheet with desired CodeName is found 
For Each sh in ThisWorkbook.WorkSheets 

    ' Say the codename you're interested in is Sheet1 
    If sh.CodeName = "Sheet1" Then 

     ' If you didn't want to refer to this sheet later, 
     ' you could do all necessary operations here, and never use shName 
     ' or the later With block 

     ' If you do want to refer to this sheet later, 
     ' you will need to store either the Name or Index (below shows both) 

     ' Store sheet's Name 
     shName = sh.Name 

     ' Store sheet's Index 
     shIndex = sh.Index 

     Exit For 

    End If 

Next sh 


' Check if match was found, do stuff as before if it was! 
If shName = "" Then 

    MsgBox "Could not find matching codename" 

Else 

    ' Equally to the next line, could use Worksheets(shIndex) 
    With Worksheets(shName) 
     '<stuff here> 
    End With 

End If 

[1] https://msdn.microsoft.com/en-us/library/office/ff837552.aspx

Answer 2

利用、二重引用符彼らは変数宣言されたかのようにあなたのコードに直接シートコードネームを使用する前とSheet1

With Worksheets("Sheet1") '* Error here 
    'my code here 
End With 

Answer 3

後：

Sub UsingSheetCodeName() 
    With Sheet1 
     .[a1] = Sheet1.Name 
    End With 
End Sub 

Answer 4

コード内でWorksheet.Indexを使用するには：

With Worksheets(1) ' << this is the index for Sheet1 
    .Range("A1").Value = "Test" ' modify the value in cell A1 
End With 

Answer 5

多分このコードは、異なる名前Sインデックス

Sub DisplaySheetnames() 

    Dim wks As Worksheet 
    For Each wks In Worksheets 
     Debug.Print "Index", wks.Index, "of sheet with name: " & wks.Name, "and", "codename " & wks.CodeName 
    Next 

End Sub