、各サンプルから算出したROC曲線を比較したいです。 http://support.sas.com/kb/45/339.htmlからわかるように、SASは1つのPROCステップで独立したサンプルのROC曲線を比較することはできません。あなたは自分で仕事をしなければなりません。
プロセスである:
- 実行PROC LOGISTIC各サンプルについて、標準エラーでROC統計(各カット点の感度/特異性)とのAUCを計算します。
- ROC統計のプロットを作成し、2つの曲線をオーバーレイします。
- AUCから検定統計量とp値を計算します。
以下は私の例です。私はこれが正しいと約束しているわけではありませんが、それは私がサポートノートの情報を理解したことです。サポートノートをお読みください。
サンプルデータ。私はまだあなたのデータを理解していないので、私は理解しているものを作った。 5人の女性と6人の男性のデータ。各人は、いくつかの診断検査のスコアと疾患の状態(1/0)を持っています。
data have;
input Sex $1. Test Disease;
cards;
F 10 0
F 20 0
F 30 1
F 40 0
F 50 1
M 10 0
M 20 1
M 30 0
M 40 1
M 50 1
M 60 1
;
run;
PROCロジスティックを実行し、統計を出力します。私は男性と女性のための別々のPROCステップを実行するのではなく、BYステートメントを使用しました。
ods output ROCassociation=AUCs(where=(ROCmodel="Test"));
proc logistic data=have plots(only)=roc;
model Disease(event='1') = Test
/outroc=RocStats(where=(_source_="Test"))
;
roc 'Test' Test;
by Sex;
run;
ods output close;
オーバーラップしたROC曲線をプロットするためにSGPLOTを使用します。私は9.3を使用しているので、正方形のプロットを強制的にODSのグラフィックスステートメントを使用する必要があります。 9.4は、SGPLOTにaspect = 1オプションを導入しました。それはまっすぐなプロットで、SGPLOTとGTLをどれだけ愛しているかを思い出させます。私はGPLOTに戻るつもりはないと思う。
ods graphics/height=480px width=480px;
proc sgplot data=RocStats;
xaxis values=(0 to 1 by 0.25) grid offsetmin=.05 offsetmax=.05;
yaxis values=(0 to 1 by 0.25) grid offsetmin=.05 offsetmax=.05;
lineparm x=0 y=0 slope=1/transparency=.7;
series x=_1mspec_ y=_sensit_/group=Sex;
run;
テスト統計を計算します。サポートノートによれば、これは大規模サンプルテストです。検定統計量は、1自由度のカイ2乗分布に従う。
data AUCtest(keep=AreaMale StdErrMale AreaFemale StdErrFemale ChiSq Prob);
set AUCs (keep=Sex Area StdErr
where=(Sex='M')
rename=(Area=AreaMale StdErr=StdErrMale)
)
;
set AUCs (keep=Sex Area StdErr
where=(Sex='F')
rename=(Area=AreaFemale StdErr=StdErrFemale)
)
;
ChiSq=(AreaMale-AreaFemale)**2/(StdErrMale**2 + StdErrFemale**2);
Prob=1-probChi(ChiSq,1);
format Prob pvalue6.;
run;
この場合も、これを真実と見なさないでください。自己責任で使用すると、私は学習段階に入っています。
これは私にはまだ意味がありません。依存変数はマーカーです.1は太りすぎを意味し、0は正常を意味します。あなたの予測変数Yは体重です。だから体重(Y)が過体重の良い予測因子(Marker)であるかどうかを知りたいのですか?男性と女性のROC曲線が同じであるかどうかを確認しますか? – Quentin
男性と女性の数は同じですか? – Quentin
"ROC曲線が男性と女性で同じかどうか確認してください。"はい! "男女は同じですか?"いいえ! – Beginner