Tkxでチェックボタンで選択した値を印刷するには

Question

Tkxモジュールを使用して、@listのテキスト値が入力されたウィンドウを作成しています。次に、チェックボタンで1つ以上を選択します。 'OK'ボタンを押した後にすでに選択したものを印刷したいが、 'OK' -command => sub {}に変数を渡す方法はわからない。ありがとう。

use autodie; 
use strict; 
use warnings; 
use Tkx; 

my $mw = Tkx::widget->new("."); 
$mw->g_wm_title("Listbox"); 
$mw->m_configure(-background => "#191919"); 

my $width = '700'; 
my $height = '500'; 

Tkx::update('idletasks'); 
$width ||= Tkx::winfo('reqwidth', $mw); 
$height ||= Tkx::winfo('reqheight', $mw); 

my $x = int((Tkx::winfo('screenwidth', $mw)/2) - ($width/2)); 
my $y = int((Tkx::winfo('screenheight', $mw)/2) - ($height/2)); 

$mw->g_wm_geometry($width . "x" . $height . "+" . $x . "+" . $y); 

my @list = ('TEXT1', 'TEXT2', 'TEXT3', 'TEXT4', 'TEXT5'); 

for my $list (@list) { 
    my $cb = $mw->new_ttk__checkbutton(
     -text => $list, 
     -onvalue => 1, 
     -offvalue => 0, 
    ); 
    $cb->g_pack(
     -anchor=>'w', 
     -side=>'top', 
     -fill => 'x' 
    ); 
} 

my $ok = $mw->new_button(
    -text => "OK", 
    -command => sub {  
     print "Selected Values"; 
     Tkx::after(500, sub { $mw->g_destroy }); 
    }, 
); 

$ok->g_pack(
    -anchor=>'c', 
    -side=>'bottom', 
); 

Tkx::MainLoop(); 

Answer 1

あなただけのチェックボックスが選択されているものを検索する場合：

my $settings; 
for my $list (@list) { 
    my $cb = $mw->new_ttk__checkbutton(
     -text => $list, 
     -onvalue => 1, 
     -offvalue => 0, 
     -variable => \$settings->{checkbuttons}->{$list}, 
    ); 
    $cb->g_pack(
     -anchor=>'w', 
     -side=>'top', 
     -fill => 'x' 
    ); 
} 

my $ok = $mw->new_button(
    -text => "OK", 
    -command => sub {  
     print "Selected Values: ["; 

     print join(", ", grep { $settings->{checkbuttons}->{$_} } @list), "]\n"; 
     Tkx::after(500, sub { $mw->g_destroy }); 
    }, 
);