リアルタイムバックテック出力処理

Question

これは可能かどうかわかりませんが、コマンドの出力をソケット上に送信しているので、コマンド実行中にクライアントコンピュータとサーバーコンピュータの両方に表示されます。バッククォートを使用しようとすると、コマンドが完了するまで出力が変数に保存されません。これは長い時間がかかるコマンドを実行すると悪いことです。

質問：別のプロセスを起動して変数を「監視」するという方法で、行単位で出力をスキャンする方法はありますか？

編集：これは私が、私は、出力がコマンドが完了する前に示すことを希望オープン

open DATA, "pause |" or die "Failed: $!"; 
while(defined(my $line = <DATA>)){ 
    chomp($line); 
    print "$line\n"; 
} 

と試みたものです。

Answer 1

あなたは正しいアプローチをしています。

STDOUTに書き込む場合STDOUTは、端末（「ラインバッファリング」）であるとき、改行が検出されたとき、ほとんどのプログラムは、それらの出力をフラッシュ

my @cmd = ('perl', '-e', '$|=1; for (1..5) { print "$_\n"; sleep 1; }'); 

open(my $pipe, '-|', @cmd) 
    or die("Can't launch child: $!\n"); 

while (defined(my $line = <$pipe>)) { 
    chomp($line); 
    print "<$line>\n"; 
} 

。ほとんどのプログラムは、STDOUTが端末でない場合（「ブロックバッファリング」）、4KiBまたは8KiBの出力チャンクをブロックします。そのため、上記の例の子プログラムで$|=1;を使用しなければならなかったのです。

説明どおりに動作するプログラムは、パイプの代わりに擬似端末を使用するラインバッファリングを使用することになります。

my @cmd = ('unbuffer', 'perl', '-e', 'for (1..5) { print "$_\n"; sleep 1; }'); 

open(my $pipe, '-|', @cmd) 
    or die("Can't launch child: $!\n"); 

while (defined(my $line = <$pipe>)) { 
    chomp($line); 
    print "<$line>\n"; 
} 

IPC::Runは、擬似端末を作成するネイティブな方法を提供します。

use IPC::Run qw(run); 

my @cmd = ('perl', '-e', 'for (1..5) { print "$_\n"; sleep 1; }'); 

my $buf = ''; 
run(\@cmd, '>pty>', sub { 
    $buf .= $_[0]; 
    while ($buf =~ s/^(.*)\r\n//) { 
     print "<$1>\n"; 
    } 
});