プロローグに行列を転記する方法

Question

[[1,2,3][4,5,6][6,7,8]]のようなリストを[[1,4,6],[2,7,8],[3,6,9]]に転記するにはどうすればよいですか？

それを表現するには：行列を左に90度反転したいと思います。どうやってやるの？ここで

Answer 1

わかりません。ノーならば（そうでなければ

1 ?- transpose([[1,2,3],[4,5,6],[6,7,8]], X). 
X = [[1, 4, 6], [2, 5, 7], [3, 6, 8]]. 

：このように、あなたがtranspose/2述語を使用できるように

:- use_module(library(clpfd)).

：SWI-PROLOGを使用している場合

、あなたはそうのように、CLPFD moduleを使用することができますSWI-PROLOG）では、単にSWIのclpfdの古いものであったこの実装を使うことができます：

transpose([], []). 
transpose([F|Fs], Ts) :- 
    transpose(F, [F|Fs], Ts). 

transpose([], _, []). 
transpose([_|Rs], Ms, [Ts|Tss]) :- 
     lists_firsts_rests(Ms, Ts, Ms1), 
     transpose(Rs, Ms1, Tss). 

lists_firsts_rests([], [], []). 
lists_firsts_rests([[F|Os]|Rest], [F|Fs], [Os|Oss]) :- 
     lists_firsts_rests(Rest, Fs, Oss). 

foldlとmaplistビルトインを使用する最新バージョンについては、clpfd.plを参照してください。

Answer 2

はa fragment of a larger answerです：あなたの例が正しいですが、私はアイデアを得る

% transposed(+A, ?B) iff matrix B is transposed matrix A 
transposed(A, B) :- transposed(A, [], B). 
transposed(M, X, X) :- empty(M), !. 
transposed(M, A, X) :- columns(M, Hs, Ts), transposed(Ts, [Hs|A], X). 

% empty(+A) iff A is empty list or a list of empty lists 
empty([[]|A]) :- empty(A). 
empty([]). 

% columns(+M, ?Hs, ?Ts) iff Hs is the first column 
% of matrix M and Ts is the rest of matrix M 
columns([[Rh|Rt]|Rs], [Rh|Hs], [Rt|Ts]) :- columns(Rs, Hs, Ts). 
columns([[]], [], []). 
columns([], [], []). 

Answer 3

反復アプローチ：より良い理解のための完全な名前を持つ

trans([H|R],[H1|R1]):-trans2([H|R],[H|R],[],[H1|R1],0),!. 
trans2([A|_],_,_,[],N):-length(A,N). 
trans2(M,[],H1,[H1|R1],N):-N1 is N+1, trans2(M,M,[],R1,N1). 
trans2(M,[H|R],L,[H1|R1],N):-nth0(N,H,X), 
    append(L,[X],L1),trans2(M,R,L1,[H1|R1],N). 

Answer 4

私のソリューション：

% emptyMatrix(Line, EmptyMatrix) 
emptyMatrix([],[]). 
emptyMatrix([_|T1],[[]|T2]):-emptyMatrix(T1,T2). 
% only length of parameter 'Line' is interesting. It ignores its content.  

% appendElement(Element, InputList, OutputList) 
appendElement(E,[],[E]). 
appendElement(E,[H|T],[H|L]):-appendElement(E,T,L). 

% appendTransposed(NestedList, InputMatrix, OutputMatrix) 
appendTransposed([],[],[]). 
appendTransposed([X|T1],[],[[X]|T3]):-appendTransposed(T1,[],T3). 
appendTransposed([X|T1],[R|T2],[C|T3]):-appendElement(X,R,C),appendTransposed(T1,T2,T3). 

% transposeMatrix(InputMatrix, TransposedMatrix) 
transposeMatrix([L|M],T):-emptyMatrix(L,A),transpose([L|M],T,A). 
transpose([],T,T). 
transpose([L|M],T,A):-appendTransposed(L,A,B),transpose(M,T,B). 

A 'ラインは' COLまたは行することができます。

アイデアは空の行列のリストに要素を追加することにあります。 （例えば、最初の行のすべての要素=全てのCOLSの最初の要素を第1のi番目の行の =>すべての要素=全てのCOLSのi番目の要素）

それはこのセッションとして私のマシン上で動作しますプロトコルは、私に示しています

5 ?- transposeMatrix([[1,2],[3,4]],T). 
T = [[1, 3], [2, 4]] ; 
false. 

6 ?- transposeMatrix([[1],[2]],T). 
T = [[1, 2]] ; 
false. 

7 ?- transposeMatrix([[1,2,3],[4,5,6]],T). 
T = [[1, 4], [2, 5], [3, 6]] ; 
false. 

8 ?- transposeMatrix([[1]],T). 
T = [[1]] ; 
false. 

Answer 5

単純なアプローチ：また

trans(M, [P|T]):- first(M, P, A), trans(A, T). 
trans(Empty, []):- empty(Empty). 

empty([[]|T]):- empty(T). 
empty([[]]). 

first([[P|A]|R], [P|Ps], [A|As]):- first(R, Ps, As). 
first([], [], []). 

効率的

[debug] 36 ?- time(trans([[1,2,3],[4,5,6],[7,8,9]],A)). 
% 21 inferences, 0.000 CPU in 0.000 seconds (?% CPU, Infinite Lips) 
A = [[1,4,7],[2,5,8],[3,6,9]] ; 
% 12 inferences, 0.000 CPU in 0.000 seconds (?% CPU, Infinite Lips) 
false. 

Answer 6

これは私が思いつくことができる最短の答えです。ただし、差分リストを使用して末尾再帰を有効にすることができます。

transpose([[]|_], []). 
transpose(M, [X|T]) :- row(M, X, M1), 
         transpose(M1, T). 
row([], [], []). 
row([[X|Xs]|Ys], [X|R], [Xs|Z]) :- row(Ys, R, Z). 

Answer 7

別のアプローチ：

delete_one_list([], []). 
delete_one_list([[_|L]|LLs], [L|Ls]) :- 
    delete_one_list(LLs, Ls). 

transpose_helper([], []). 
transpose_helper([[X|_]|Xs], [X|Ys]) :- 
    transpose_helper(Xs, Ys). 

transpose([[]|_], []). 
transpose(List, [L|Ls]) :- 
    transpose_helper(List, L), 
    delete_one_list(List, NewList), 
    transpose(NewList, Ls).