Mooseコンストラクタがundef引数を無視するようにします。

Question

ハッシュテーブルはPerlオブジェクトの典型的な初期化子です。これで、指定されたキーが定義された値になるかどうか、またはキーがまったく存在するかどうかがわからないという点で、入力が信頼できません。今度は、そのような信頼できない入力をMooseオブジェクトに供給したいのですが、欠けているキーは完全に大丈夫ですが、未定義の値を取り除きたいので、未定義の属性でいっぱいのオブジェクトにならないようにします。

オブジェクトをインスタンス化して未定義の値をフィルタリングする際には、十分注意する必要があります。しかし、それが1つの場所にあるので、コンストラクタにそのフィルタをインストールしたいとしましょう。コンストラクタに未定義の値を無視させ、それらに遭遇すると死ぬことは望ましくありません。

アクセサメソッドの場合は、aroundを使用して、属性をundefに設定しないようにすることができます。しかし、method modifiersはコンストラクタのために呼び出されるのではなく、アクセサのためだけに呼び出されます。 c'torと同じ効果を得るために、つまりundef属性が受け入れられないようにするために、Mooseにも同様の機能がありますか？

属性がundefの場合、Moose Anyタイプはオブジェクトにハッシュキーを作成することに注意してください。 %$selfにはundefの値が含まれないようにしたいので、私は望んでいません。

ここで私がやったいくつかのテストです：

package Gurke; 
use Moose; 
use Data::Dumper; 

has color => is => 'rw', isa => 'Str', default => 'green'; 
has length => is => 'rw', isa => 'Num'; 
has appeal => is => 'rw', isa => 'Any'; 

around color => sub { 
    # print STDERR Dumper \@_; 
    my $orig = shift; 
    my $self = shift; 
    return $self->$orig unless @_; 
    return unless defined $_[0]; 
    return $self->$orig(@_); 
}; 

package main; 
use Test::More; 
use Test::Exception; 

my $gu = Gurke->new; 
isa_ok $gu, 'Gurke'; 
diag explain $gu; 
ok ! exists $gu->{length}, 'attribute not passed, so not set'; 
diag q(attempt to set color to undef - we don't want it to succeed); 
ok ! defined $gu->color(undef), 'returns undef'; 
is $gu->color, 'green', 'value unchanged'; 
diag q(passing undef in the constructor will make it die); 
dies_ok { Gurke->new(color => undef) } 
    'around does not work for the constructor!'; 
lives_ok { $gu = Gurke->new(appeal => undef) } 'anything goes'; 
diag explain $gu; 
diag q(... but creates the undef hash key, which is not what I want); 
done_testing; 

Answer 1

これはまさにMooseX::UndefTolerantの機能です。クラスを不変にすると、生成されたコンストラクタにコードがインライン展開されるため、独自のBUILDARGSメソッドを作成するよりもはるかに高速になります。

Answer 2

はちょうどあなた自身のBUILDARGSサブルーチンを提供しています。

package Gurke; 

... 

around 'BUILDARGS' => sub{ 
    my($orig,$self,@params) = @_; 
    my $params; 
    if(@params == 1){ 
    ($params) = @params; 
    }else{ 
    $params = { @params }; 
    } 

    for my $key (keys %$params){ 
    delete $params->{$key} unless defined $params->{$key}; 
    } 

    $self->$orig($params); 
}; 

Answer 3

私はそれが多少重複努力であることを認識していますが、BUILDARGSでctorのをフックすることができます

around BUILDARGS => sub { 
    my $orig = shift; 
    my $class = shift; 
    my %params = ref $_[0] ? %{$_[0]} : @_; 

    return $class->$orig(
     map { $_ => $params{$_} } 
     grep { defined $params{$_} } 
     keys %params 
    ); 
}; 

編集：編集CTORに渡されたとしても、参照をサポートします。

Answer 4

この例題は、コンストラクタに渡されたundef属性を処理したいという欲求に触発されていますが、質問自体はundefだけをコンストラクタに渡すケースを意味します。解決する。例えば、Class->new(undef)。

bvr's BUILDARGS answerが好きです。コンストラクタへの唯一の引数としてハッシュリファレンスの代わりにはundef値を渡す場合に対処するように拡張することができます。

around BUILDARGS => sub { 
    my $orig = shift; 
    my $class = shift; 
    my %params = defined $_[0] ? ref $_[0] ? %{$_[0]} : @_ :(); 

    return $class->$orig(
     map { $_ => $params{$_} } 
     grep { defined $params{$_} } 
     keys %params 
    ); 
}; 

MooseX ::はUndefTolerantはこのケースをサポートするためには表示されません。