XSLT、連結フィールド一緒

Question

私は別のフィールド上の特定のフィールドと連結でフィルタしようとしています

：

入力：

<?xml version="1.0" encoding="UTF-8"?> 
<payloads> 
    <payload> 
     <firstname>michael</firstname> 
     <secondname>brown</secondname> 
     <number>1</number> 
    </payload> 
    <payload> 
     <firstname>michael</firstname> 
     <secondname>brown</secondname> 
     <number>2</number> 
    </payload> 
    <payload> 
     <firstname>michael</firstname> 
     <secondname>brown</secondname> 
     <number>3</number> 
    </payload> 
</payloads> 

出力：私は私がする必要があることを知っている

<?xml version="1.0" encoding="UTF-8"?> 
<payloads> 
    <payload> 
     <firstname>michael</firstname> 
     <secondname>brown</secondname> 
     <number>1,2,3</number> 
    </payload> 
</payloads> 

各ペイロードタグをループしますが、現時点では正しく出力されません。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 

    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="payloads"> 
     <xsl:copy> 
      <xsl:for-each select="payload"> 
       <payload> 
        <xsl:value-of select="firstname"/> 
        <xsl:value-of select="secondname"/> 
        <xsl:value-of select="number"/> 
       </payload> 
      </xsl:for-each> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 1

このテンプレートを使用：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 
    <xsl:key name="k" match="payload" use="concat(firstname, '|', secondname)"/> 

    <xsl:template match="payload[generate-id() = 
        generate-id(key('k', concat(firstname, '|', secondname)))]"> 
     <xsl:copy> 
      <xsl:copy-of select="firstname"/> 
      <xsl:copy-of select="secondname"/> 
      <number> 
       <xsl:for-each select="key('k', concat(firstname, '|', secondname))"> 
        <xsl:value-of select="number"/> 

        <xsl:if test="position() != last()"> 
         <xsl:text>,</xsl:text> 
        </xsl:if> 
       </xsl:for-each> 
      </number> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="payload"/> 

    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

提供された入力XMLに適用された場合、それは望んでいた正しい結果出力：だから実際には、あなたがしたい

<payloads> 
    <payload> 
    <firstname>michael</firstname> 
    <secondname>brown</secondname> 
    <number>1,2,3</number> 
    </payload> 
</payloads>