Gnuplot：画像のプロット時にラベルが表示されない

Question

gnuplotで画像をプロットすると、設定したラベルは表示されません。それ以外はすべて正しいです。ここに私のコードは次のとおりです。

#! /bin/sh 
# 
# Plotting the color map of correlation using the default Matlab palette 
# 
gnuplot <<EOF 
reset 
set terminal pngcairo size 700,524 enhanced font 'Verdana,10' 
unset key 
# border 
set style line 11 lc rgb '#808080' lt 1 
set border 3 front ls 11 
set tics nomirror out scale 0.75 

set xrange [0:20] 
set yrange [0:20] 
set xlabel 'Distance x/D_j [-]' 
set ylabel '{/Symbol t} u_j/D_j [-]' 

# disable colorbar tics 
set cbtics scale 0 
# matlab palette colors 
set palette defined (0 "#000090",\ 
         1 "#000fff",\ 
         2 "#0090ff",\ 
         3 "#0fffee",\ 
         4 "#90ff70",\ 
         5 "#ffee00",\ 
         6 "#ff7000",\ 
         7 "#ee0000",\ 
         8 "#7f0000") 

set output 'test.png' 
set label 'aaa' at 2,17 
plot 'Cuup_nf_a090_r050Dj_average' u 1:2:3 with image 
EOF 

奇妙である何ことです：私は、例えば、第3のデータシリーズとして存在していない列を使用してデータファイルをプロットした場合：

plot 'Cuup_nf_a090_r050Dj_average' u 1:2:4 with image 

（私が持っています'Cuup_nf_a090_r050Dj_average'ファイルの3列のみ）

確かに、私のイメージには空白（データなし）しか表示されませんが、ラベルは正しく表示されます。

それはラベルが私のデータパレットで覆われているようです...私は、コードの最後に 'set label'を入れようとしましたが、どちらも動作しません。

誰かがアイデアを持っていますか？

PS：私のgnuplotのバージョン：バージョン4.6パッチレベル4

事前にどうもありがとう。

Answer 1

ラベルには、前面または背面のレイヤーに配置するオプションfront|backがあります。 with imageをプロットする際に隠されているラベルは、明示的なレイヤを指定しないように、デフォルトの設定は、backです：

$data <<EOD 
1 2 
3 4 
EOD 
set label 'default, hidden' at graph 0.6, graph 0.7 font ",20" 
set label back 'back, hidden' at graph 0.6, graph 0.5 font ",20" 
set label front 'front, visible' at graph 0.6, graph 0.3 font ",20" 

plot $data matrix with image