CMakeのFIND_PACKAGEの統一

Question

CMakeのFIND_PACKAGEからのインクルードパスとライブラリパスを取得する際に統一された出力用語を得るための秘訣はありますか？

時にはFOO_INCLUDEです。時にはFOO_INCLUDE_PATHです。など

たとえば、FOO_INCLUDEとFOO_LIBが、FIND_PACKAGEの呼び出し後にFOO_FOUNDがTRUEに設定されているときに常に定義されるようにする方法を探したいと思います。

Answer 1

はFoo::FooのようなIMPORTED標的を提供行うインクルードパス、ライブラリなどの依存関係とその変数表記現代find_packageの実装を知る必要性を避けるために答え

に私のコメントを回します。しかし、これは - @ Tsyvarevがコメントしたように - CMakeのfind modulesのすべてを通して統一されたものとは限りません。だから、一般化

CMake's Sample Find Module implementation次のように上書き find_package()マクロバージョンを使用して find_package()通話を統一することができます：

cmake_minimum_required(VERSION 3.2) 

project(UnifiedFindPackage) 

macro(unify_vars _result) 
    set(${_result} "") 
    foreach(_i IN ITEMS ${ARGN}) 
     if (${_i}) 
      list(APPEND ${_result} "${${_i}}") 
     endif() 
    endforeach() 
endmacro() 

macro(find_package _name) 
    _find_package(${_name} ${ARGN}) 
    if (${_name}_FOUND AND NOT TARGET ${_name}::${_name}) 
     add_library(${_name}::${_name} STATIC IMPORTED GLOBAL) 
     unify_vars(_var ${_name}_LIBRARY ${_name}_LIB) 
     if (_var) 
      set_target_properties(${_name}::${_name} PROPERTIES IMPORTED_LOCATION "${_var}") 
     endif() 
     if (${_name}_LIBRARY_RELEASE) 
      set_property(TARGET ${_name}::${_name} APPEND PROPERTY IMPORTED_CONFIGURATIONS RELEASE) 
      set_target_properties(${_name}::${_name} PROPERTIES IMPORTED_LOCATION_RELEASE "${${_name}_LIBRARY_RELEASE}") 
     endif() 
     if (${_name}_LIBRARY_DEBUG) 
      set_property(TARGET ${_name}::${_name} APPEND PROPERTY IMPORTED_CONFIGURATIONS DEBUG) 
      set_target_properties(${_name}::${_name} PROPERTIES IMPORTED_LOCATION_DEBUG "${${_name}_LIBRARY_DEBUG}") 
     endif()    
     if (${_name}_LIBRARIES) 
      set_property(TARGET ${_name}::${_name} APPEND PROPERTY INTERFACE_LINK_LIBRARIES "${${_name}_LIBRARIES}") 
     endif() 
     unify_vars(_var ${_name}_INCLUDE_DIRS ${_name}_INCLUDE_PATH) 
     if (_var) 
      set_property(TARGET ${_name}::${_name} APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES "${_var}") 
     endif() 
     unify_vars(_var ${_name}_COMPILE_FLAGS ${_name}_DEFINITIONS) 
     if (_var) 
      set_property(TARGET ${_name}::${_name} APPEND PROPERTY INTERFACE_COMPILE_OPTIONS "${_var}") 
     endif() 
    endif()    
endmacro() 

find_package(MPI REQUIRED) 

add_executable(${PROJECT_NAME} main.c) 
target_link_libraries(${PROJECT_NAME} MPI::MPI) 

これが唯一の可能な統一を実証しなければならないし、上の根拠が必要-によって拡張することができます。

編集：これをコミュニティのWiki回答に変えてください。気軽に投稿してください。

コードはこの例ではMPIモジュールの検索結果でテストされました。