Excel VBA - シートプロパティはフィールドを割り当てません。

Question

VBAの新機能 - OOP言語でゲッターとセッターを使用するようなシートプロパティを使用しようとしています。私は（明確にするために簡略化）シート1に次のコードを持っている：

Option Explicit 

Private bAllowChange As Boolean 

Public Property Let AllowChange(bLetAllowChange As Boolean) 
    bAllowChange = bLetAllowChange 
End Property 

IはAllowChangeプロパティは、別のモジュール内のサブによって呼び出されたときに、bAllowChangeフィールドはそれに応じて更新されることが期待されます。 VBEのデバッグ機能を使用することにより、私はAllowChangeが正しい値（bLetAllowChangeが正しい値をとる）が、bAllowChangeに値を割り当てていないライン

bAllowChange = bLetAllowChange 

を渡されていることがわかります。 bAllowChangeをPublicに設定すると、期待どおりに動作しますが、これは最初にプロパティを使用する目的に反するものです。これはおそらくVBAの範囲について理解していない単純なものです。助言がありますか？前もって感謝します。

Answer 1

私のために、次の作品：Module1ので

：シートで

Option Explicit 

Sub SetItToFalse() 
    Sheet1.AllowChange = False 
End Sub 
Sub SetItToTrue() 
    Sheet1.AllowChange = True 
End Sub 

Sheet1のコードネームを持つ：

Option Explicit 

Private bAllowChange As Boolean 

Public Property Let AllowChange(bLetAllowChange As Boolean) 
    bAllowChange = bLetAllowChange 
End Property 
Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
    MsgBox bAllowChange 
End Sub 

設定しているコードでは、私が呼び出すことができますSetItToFalseサブルーチンを実行して、すべての選択変更が私にそれがFalseであることを示しています。 SetItToTrueを呼び出すと、すべての選択変更が私に表示されます。それはTrueです。

Answer 2

あなたが永続的な性質をしたい場合は、（更新/カスタムプロパティを削除/取得/設定する方法のほんの一例）これを試して

Sub customProperties() 

    ActiveWorkbook.Sheets("Sheet1").customProperties.Add "abc123", 123 
    Debug.Print ActiveWorkbook.Sheets("Sheet1").customProperties(1)  ' custom properties are not indexed by name 

    ActiveWorkbook.Sheets("Sheet1").customProperties(1).Value = "this is my data" 
    Debug.Print ActiveWorkbook.Sheets("Sheet1").customProperties(1) 

    ActiveWorkbook.Sheets("Sheet1").customProperties(1).Delete 


    ' CustomDocumentProperties Types 
    ' msoPropertyTypeBoolean 2 
    ' msoPropertyTypeDate  3 
    ' msoPropertyTypeFloat 5 
    ' msoPropertyTypeNumber 1 
    ' msoPropertyTypeString 4 


    ActiveWorkbook.CustomDocumentProperties.Add Name:="xyz", LinkToContent:=False, Type:=msoPropertyTypeString, Value:="xyz" 
    Debug.Print ActiveWorkbook.CustomDocumentProperties("xyz") 

    ActiveWorkbook.CustomDocumentProperties("xyz").Value = "abcdefg" 
    Debug.Print ActiveWorkbook.CustomDocumentProperties("xyz") 

    ActiveWorkbook.CustomDocumentProperties("xyz").Delete 

End Sub 

Answer 3

あなたのカスタムワークシートのプロパティ値を格納するためのワークシートの名前のコレクションを使用することができます永久に。

この主な注意点は、値に等号が前に付いて返されることです。 （たとえば、name.Value = Trueを設定した後、name.Valueは= =Trueとなります）。私は私の例でこれを回避する方法をとった。

---

Public Property Let AllowChange(bLetAllowChange As Boolean) 
    Dim n As Name 
    On Error Resume Next 
    Set n = Me.Names("bLetAllowChange") 
    If n Is Nothing Then 
     Set n = Me.Names.Add("bLetAllowChange", bLetAllowChange) 
    End If 
    n.Value = bLetAllowChange 
    On Error GoTo 0 
End Property 

Public Property Get AllowChange() As Boolean 
    Dim result As String 
    On Error Resume Next 
    result = Me.Names("bLetAllowChange").Value 
    result = Right(result, Len(result) - 1) 
    AllowChange = Application.Evaluate(result) 
    On Error GoTo 0 
End Property