マクロExcel：ユーザーフォームにマクロを割り当てます。

Question

xとyの数を計算するコードがあります（実際には列と行です）。ユーザーフォームにコードを挿入して機能させるにはどうすればよいですか？次に、各xとyのデータをキー入力して「OK」を押すと、出力がワークシートに表示されます。 「OK」の部分にはどのようなコードを使用しますか？また、「キャンセル」の部分も同様です。私はまだVBAコードが新しくなっています。

マイコード：

Sub InsertShapeRange() 

Dim my_row As Integer 
Dim my_col As Integer 
Dim Rng As Range 
Dim shp As Shape 
Dim ws As Worksheet 

my_col = Application.InputBox("No. of x dies?", "Wafer Map", Default:=0) 
my_row = Application.InputBox("No. of y dies?", "Wafer Map", Default:=0) 

Set Rng = Selection 
Set Rng = Rng.Resize(my_row, my_col) 
Set ws = Rng.Parent 
Set shp = ws.Shapes.AddShape(1, Rng.Left, Rng.Top, Rng.Width, Rng.Height) 
With shp 
    .Fill.Visible = msoFalse 
    With .Line 
     .Visible = msoTrue 
     .ForeColor.RGB = RGB(0, 0, 0) 
     .Transparency = 0 
    End With 
End With 
With Rng 
    .Borders(xlInsideHorizontal).LineStyle = xlContinuous 
    .Borders(xlInsideVertical).LineStyle = xlContinuous 
End With 
End Sub 

以下に示すように、私はユーザーフォームを持っています。

Answer 1

あなたのサブルーチンにパラメータを追加することができます。変数は今、サブ定義で定義されている通ります。次に、これらの行を削除する必要があります

Sub InsertShapeRange(my_col As Integer, my_row As Integer) 

：ボタンを右クリックして、クリックすると

Dim my_row As Integer 
Dim my_col As Integer 

my_col = Application.InputBox("No. of x dies?", "Wafer Map", Default:=0) 
my_row = Application.InputBox("No. of y dies?", "Wafer Map", Default:=0) 

今すぐごOK]ボタンのコードを追加し、ビューコードを選択します。

Private Sub cmdOK_Click() 
    InsertShapeRange txtXDies, txtYDies 
    Me.Hide 
End Sub 

[OK]ボタンの[既定]プロパティを[True]に設定すると、[Enter]キーを押しても同じことができます。 CancelプロパティがFalseに設定されていることを確認します。キャンセルボタンの

OK Button Default property = True

、フォームを非表示にするには、次のコードを入力してください。

Private Sub cmdCancel_Click() 
    Me.Hide 
End Sub 

最後に、CancelボタンのCancelプロパティをTrueに設定します。これにより、Escapeキーをクリックするのと同じことができます。また、DefaultをFalseに設定します。

Cancel Property of Cancel Button = True

完成したフォームのコードモジュールには、次のようになります。

Option Explicit 

Private Sub cmdCancel_Click() 
    Me.Hide 
End Sub 

Private Sub cmdOK_Click() 
    InsertShapeRange txtXDies, txtYDies 
    Me.Hide 
End Sub 

完成InsertShapeRangeサブルーチンは、次のようになります。

Sub InsertShapeRange(my_col As Integer, my_row As Integer) 

    Dim Rng As Range 
    Dim shp As Shape 
    Dim ws As Worksheet 

    Set Rng = Selection 
    Set Rng = Rng.Resize(my_row, my_col) 
    Set ws = Rng.Parent 
    Set shp = ws.Shapes.AddShape(msoShapeRectangle, Rng.Left, Rng.Top, Rng.Width, Rng.Height) 
    With shp 
     .Fill.Visible = msoFalse 
     With .Line 
      .Visible = msoTrue 
      .ForeColor.RGB = RGB(0, 0, 0) 
      .Transparency = 0 
     End With 
    End With 
    With Rng 
     .Borders(xlInsideHorizontal).LineStyle = xlContinuous 
     .Borders(xlInsideVertical).LineStyle = xlContinuous 
    End With 

End Sub 

私の例ではテキストボックスは "cmdCancel" "txtXDies" と "txtYDies"、OKボタン "cmdOK" と命名し、ボタンをキャンセルしています。プロパティウィンドウで名前を確認したり、名前を変更したりできます。F4キーを押しながらオブジェクトをクリックします。