VBA：オブジェクトはこのプロパティまたはメソッドをサポートしていません

Question

非常に単純なマクロを作成しました。このブックから別のブックと選択した範囲のデータを開きます。 しかし、私はこの警告を受け取り続けます：オブジェクトはこのプロパティまたはメソッドをサポートしていません

何が問題なのですか？

Sub data() 
Dim wb As Workbook 
Dim ws As Worksheet 
Dim filename As String 
Dim lastrow As Integer 
Dim lastcolumn As Integer 
Dim range_to_copy As Range 

'open workbook 
filename = "C:\Users\mk\Desktop\sales report\Sales Report.xls" 
Set wb = Workbooks.Open(filename) 
Set ws = wb.Sheets("data") 

lastcolumn = wb.ws.Cells(1, wb.ws.Columns.Count).End(xlToLeft).Column 
lastrow = wb.ws.Cells(wb.ws.Roows.Count, 1).End(xlToLeft).Row 

range_to_copy = Range("Cells(1,1):Cells(lastrow,lastcolumn)") 

End sub 

Answer 1

コードにいくつかの誤りがあります。 試用

lastcolumn = ws.Cells(1, ws.Columns.Count).End(xlToLeft).Column 
lastRow = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row 

Set range_to_copy = Range(ws.Cells(1, 1), ws.Cells(lastRow, lastcolumn)) 

Answer 2

多くのことが間違っています。

編集：
Dim lastrow As Integer Dim lastcolumn As Integer
Integerは32,767までの数値を格納することができます。これは列には問題ありませんが、行番号にオーバーフローエラーが発生します。 Longのデータ型を使用する方が良いでしょう - 数字は2,147,486,647までです。
lastcolumn = ws.Cells(1, ws.Columns.Count).End(xlToLeft).Column

lastrow = wb.ws.Cells(wb.ws.Roows.Count, 1).End(xlToLeft).Row
Rowsはそれだけで1 oを持っている：あなただけの必要があるので

ws変数はすでにワークブックを参照します。
編集：xlToLeft右端のセルを見て、左に動作します。あなたは行を探しているので、最後のセルを見て、働くxlUpを使う必要があります。

range_to_copy = Range("Cells(1,1):Cells(lastrow,lastcolumn)")
これはオブジェクトなので、Setです。セル参照はコンマで区切られており、文字列として保持しないでください。

Sub data() 
    Dim wb As Workbook 
    Dim ws As Worksheet 
    Dim filename As String 
    Dim lastrow As Long 
    Dim lastcolumn As Long 
    Dim range_to_copy As Range 

    'open workbook 
    filename = "C:\Users\mk\Desktop\sales report\Sales Report.xls" 
    Set wb = Workbooks.Open(filename) 
    Set ws = wb.Sheets("data") 

    lastcolumn = ws.Cells(1, ws.Columns.Count).End(xlToLeft).Column 
    lastrow = ws.Cells(ws.Rows.Count, 1).End(xlUp).Row 

    Set range_to_copy = ws.Range(ws.Cells(1, 1), ws.Cells(lastrow, lastcolumn)) 

End Sub 

注：すべての範囲参照には、ワークシート参照が先行しています。これがなければ、常に現在アクティブなシートを見るので、dataシートにない場合、2番目のセル参照がアクティブシートを見るので、次のことは失敗します。
ws.Range(ws.Cells(1, 1), Cells(lastrow, lastcolumn))

コードブロックWith....End Withをチェックする価値があります。

Answer 3

あなたが定義されており、あなたのwsワークシートオブジェクトを設定したら、あなたはwsワークシートオブジェクトが完全にwbワークブックにSheets("data")でquallifiedされているので、もうwbオブジェクトを参照する必要はありません。

は今、あなたがする必要があるすべては、以下のコードのように、Withステートメントを使用している：

Set ws = wb.Sheets("data")  
With ws 
    lastcolumn = .Cells(1, .Columns.Count).End(xlToLeft).Column 
    lastrow = .Cells(.Rows.Count, 1).End(xlUp).Row 

    Set range_to_copy = .Range(.Cells(1, 1), .Cells(lastrow, lastcolumn)) 
End With