正規表現のリストをどのように一致させるのですか？

Question

私はファイルを解析していて、それの部分は、レコードのことですが、フォーマットは同様である：

CategoryA-- 
5: UserA 
6: UserB 
7: UserC 
CategoryB-- 
4: UserA 
5: UserB 

私がどのように見えるハッシュにそれを移動したい：

どう

{ UserA => { CategoryA => 5, CategoryB => 4, }, 
    UserB => { CategoryA => 6, CategoryB => 5, }, 
    UserC => { CategoryA => 7, }, 
} 

私はこれに正規表現をするのですか？

編集：これは純粋に正規表現である必要はありません。perlとループだけで良いでしょう。

Answer 1

新しいカテゴリを識別するために1つ、ユーザーレコードを解析するために2つの正規表現が必要です。

#!/usr/bin/perl 

use strict; 
use warnings; 

my %users; 
my $cur; 
while (<DATA>) { 
    if (my ($category) = /^(.*)--$/) { 
     $cur = $category; 
     next; 
    } 
    next unless my ($id, $user) = /([0-9]+): (\w+)/; 
    die "no category found" unless defined $cur; 
    $users{$user}{$cur} = $id; 
} 

use Data::Dumper; 
print Dumper \%users; 

__DATA__ 
CategoryA-- 
5: UserA 
6: UserB 
7: UserC 
CategoryB-- 
4: UserA 
5: UserB 

それとも、あなたはPerl 5.10以降を持っている場合、あなたは1つの正規表現で指定キャプチャを使用することができます。

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 

my %users; 
my $cur; 
while (<DATA>) { 
    next unless /^(?:(?<category>.*)--|(?<id>[0-9]+): (?<user>\w+))$/; 
    if (exists $+{category}) { 
     $cur = $+{category}; 
     next; 
    } 
    die "no category found" unless defined $cur; 
    $users{$+{user}}{$cur} = $+{id}; 
} 

use Data::Dumper; 
print Dumper \%users; 

__DATA__ 
CategoryA-- 
5: UserA 
6: UserB 
7: UserC 
CategoryB-- 
4: UserA 
5: UserB 

Answer 2

これはあなたのためにそれを分割します。

prompt> ruby e.rb 
[["CategoryA--", nil, nil], [nil, "5", "UserA"], [nil, "6", "UserB"], [nil, "7", "UserC"], ["CategoryB--", nil, nil], [nil, "4", "UserA"], [nil, "5", "UserB"]] 
prompt> cat e.rb 
s = <<TXT 
CategoryA-- 
5: UserA 
6: UserB 
7: UserC 
CategoryB-- 
4: UserA 
5: UserB 
TXT 
p s.scan(/(^.*--$)|(\d+): (.*$)/) 
prompt> 

Answer 3

このperlコードは、あなたの探しているもの（主に1つの変更）を行うようです。私はデータ構造を少し違った形にしましたが、それほど多くはありませんでした。

まさにここにゴルフをしようが、それは単一交互に行うことができるわけではありません

#!/usr/bin/perl 

use strict; 

my @array = (
    "CategoryA--", 
    "5: UserA", 
    "6: UserB", 
    "7: UserC", 
    "CategoryB--", 
    "4: UserA", 
    "5: UserB" 
); 

my ($dataFileContents, $currentCategory); 

for (@array) { 
    $currentCategory = $1 if (/(Category[A-Z])--/); 
    if (/(\d+): (User[A-Z])/) { 
     $dataFileContents->{$2}->{$currentCategory} = $1 
    } 

} 

Answer 4

：

my (%data, $category); 
while (<DATA>) { 
    next unless /^(?:(Category\w+)|(\d+):\s*(User\w+))/; 
    ($1 ? $category = $1 : 0) or $data{$3}{$category} = $2;  
} 

Data::Dumper（実際Smart::Comments）は出力を示しています。

{ 
    UserA => { 
      CategoryA => '5', 
      CategoryB => '4' 
      }, 
    UserB => { 
      CategoryA => '6', 
      CategoryB => '5' 
      }, 
    UserC => { 
      CategoryA => '7' 
      } 
}  

Answer 5

#!/usr/bin/perl 

use strict; 
use Data::Dumper; 

print "Content-type: text/html\n\n"; 

my ($x,%data); 
do { 
    if (/^(Category\w+)/) { 
     $x=$1; 
    } elsif (/^([0-9]+):\s*(User\w)/) { 
     if (!defined($data{$2})) { 
      $data{$2} = {$x,int($1)}; 
     } else { 
      $data{$2}{$x} = int($1); 
     } 
    } 
} while (<DATA>); 

print Dumper \%data; 


__DATA__ 
CategoryA-- 
5: UserA 
6: UserB 
7: UserC 
CategoryB-- 
4: UserA 
5: UserB 

---

RESULT ：

$VAR1 = { 
    'UserC' => { 
     'CategoryA' => 7 
       }, 
    'UserA' => { 
     'CategoryA' => 5, 
     'CategoryB' => 4 
       }, 
    'UserB' => { 
     'CategoryA' => 6, 
     'CategoryB' => 5 
    } 
};