terraformでGCP CloudSQLをセットアップする方法

Question

terraformでGCP CloudSQLをセットアップしたいと思います。私はこの文書を読んでいます。 （https://www.terraform.io/docs/providers/google/r/sql_database_instance.html）

私はそのようなコードで "terraform plan"を実行します。

resource "google_sql_database_instance" "master" { 
    name    = "terraform-master" 
    region   = "asia-northeasteast1" 
    database_version = "MYSQL_5_6" 
    project   = "test-141901" 

    settings { 
     tier = "db-f1-micro" 
     replication_type = "SYNCHRONOUS" 
     backup_configuration { 
      enabled = true 
      start_time = "17:00" 
     } 
     ip_configuration { 
      ipv4_enabled = true 
     } 
     database_flags { 
       name = "slow_query_log" 
       value = "on" 
       name = "character_set_server" 
       value = "utf8mb4" 
     } 
    } 
} 

が、私はできませんセットアップMULTIPLE database_flags

settings.0.database_flags.#:     "1" 
settings.0.database_flags.0.name:    "character_set_server" 
settings.0.database_flags.0.value:   "utf8mb4" 

どのように複数のdatabase_flagsとIセットアップCloudSQLできますか？私はその文書で "サブリストのサポート"を理解できません。

Answer 1

あなたは、複数のdatabase_flagsのブロックを使用することによってこれを行うことができるようになります。ここでは

resource "google_sql_database_instance" "master" { 
    name    = "terraform-master" 
    region   = "us-central1" 
    database_version = "MYSQL_5_6" 
    project   = "test-project" 

    settings { 
    tier    = "db-f1-micro" 
    replication_type = "SYNCHRONOUS" 

    backup_configuration { 
     enabled = true 
     start_time = "17:00" 
    } 

    ip_configuration { 
     ipv4_enabled = true 
    } 

    database_flags { 
     name = "slow_query_log" 
     value = "on" 
    } 

    database_flags { 
     name = "character_set_server" 
     value = "utf8mb4" 
    } 
    } 
} 

は、上記TFとterraform planの出力です：

+ google_sql_database_instance.master 
    database_version:        "MYSQL_5_6" 
    ip_address.#:         "<computed>" 
    name:           "terraform-master" 
    project:          "test-project" 
    region:          "us-central1" 
    self_link:         "<computed>" 
    settings.#:         "1" 
    settings.0.backup_configuration.#:   "1" 
    settings.0.backup_configuration.0.enabled: "true" 
    settings.0.backup_configuration.0.start_time: "17:00" 
    settings.0.database_flags.#:     "2" 
    settings.0.database_flags.0.name:    "slow_query_log" 
    settings.0.database_flags.0.value:   "on" 
    settings.0.database_flags.1.name:    "character_set_server" 
    settings.0.database_flags.1.value:   "utf8mb4" 
    settings.0.ip_configuration.#:    "1" 
    settings.0.ip_configuration.0.ipv4_enabled: "true" 
    settings.0.replication_type:     "SYNCHRONOUS" 
    settings.0.tier:        "db-f1-micro" 
    settings.0.version:       "<computed>"