コマンドラインで渡されたすべての引数を特定のインデックスから末尾のスクリプトに参照します。

Question

コマンドラインからバッチスクリプトにいくつかの引数を渡しています。 Like：myfile.bat flower, tree, doge, cate, house しかし、引数リストの長さは動的であり、常に5ではありません。 nからlastまでのすべての引数を取得するにはどうしたらいいですか？ たとえば、nが2の場合、doge、cate、houseを取得するにはどうすればよいですか。 コメントの質問に基づいて編集します。

Answer 1

@ECHO OFF 
SETLOCAL 
SET /a skipargs=2 
SET "destvar=somevarname" 

CALL :getargs %* 

SET somevarname 

SET /a skipargs=1 
SET "destvar=somevarname" 

CALL :getargs %* 

SET somevarname 


GOTO :EOF 

:getargs 
IF %skipargs% gtr 0 SET /a skipargs-=1&shift&GOTO getargs 
SET "%destvar%=" 
:getargsl 
IF DEFINED %destvar% (CALL SET "%destvar%=%%%destvar%%% %1" 
) ELSE (
SET "%destvar%=%1" 
) 
SHIFT 
IF "%~1" neq "" GOTO getargsl 
GOTO :eof 

これは、すべての引数の変数にn番目の後を割り当てる方法を示さなければなりません。

Answer 2

これは少し単純に、（少なくとも私にとっては）を思わ

@echo off 

set/a skip=1 & rem set skip to the number of arguments to forget 
for /L %%i in (1,1,%skip%) do shift & rem skip arguments 

:getArg 
echo %~1 & shift 
if "%~1" neq "" goto :getArg 
exit/B  

Answer 3

を試してみてください。ここ

Answer 4

を必要に応じて

@Echo Off 
Set "n=2" 
For /F "Tokens=%n%*" %%A In ("%*") Do Set "remainder=%%B" 
Echo(%remainder% 
Timeout -1 

変更2行目に、変数nの値が（これは最初_NUMSKIP引数が、すべてを表示する）%*上forループを使用してオプションである：

@echo off 
set /A "_NUMSKIP=2" 
set /A "INDEX=0" 
for %%A in (%*) do (
    set /A "INDEX+=1" 
    setlocal EnableDelayedExpansion 
    if !INDEX! GTR %_NUMSKIP% (
     endlocal 
     echo(%%A 
    ) else endlocal 
) 

これはすべての文字列に対して安全ではないことに注意してください。たとえば、引数&"&"は構文エラーを引き起こします。

---

実行へ後で転送するための単一の行の残りの引数を収集するために、これが役立つ：なる元の引数の区切り文字は、単一SPACE各により置換こと

@echo off 
set /A "_NUMSKIP=2" 
set /A "INDEX=0" & set "ARGS= " 
for %%A in (%*) do (
    set /A "INDEX+=1" 
    set "ARGV=%%A" 
    setlocal EnableDelayedExpansion 
    if !INDEX! GTR %_NUMSKIP% (
     for /F "delims=" %%B in (^""!ARGS!!ARGV!"^") do (
      endlocal 
      set "ARGS=%%~B " 
     ) 
    ) else endlocal 
) 
setlocal EnableDelayedExpansion 
echo(!ARGS:~1,-1! 
endlocal 

注意。