Inno Setupでコントロールロールアウトをアニメーション化する方法

Question

インストーラでコントロールロールアウトをアニメーション化したいと思います。

You can see this video。

Answer 1

あなたはInnoTools InnoCallback DLL library

[Files] 
Source: InnoCallback.dll; Flags: dontcopy 

[Code] 

type 
    TTimerProc = procedure(H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord); 

function SetTimer(hWnd: longword; nIDEvent, uElapse: LongWord; lpTimerFunc: LongWord): 
    LongWord; external 'SetTimer@user32.dll stdcall'; 
function KillTimer(hWnd, nIDEvent: LongWord): LongWord; 
    external 'KillTimer@User32.dll stdcall'; 

function WrapTimerProc(Callback: TTimerProc; ParamCount: Integer): LongWord; 
    external 'wrapcallback@files:innocallback.dll stdcall'; 

var 
    MainPanelAnimated: Boolean; 
    AnimationTimer: LongWord; 

procedure AnimationTimerProc(
    H: LongWord; Msg: LongWord; IdEvent: LongWord; Time: LongWord); 
var 
    L: Integer; 
begin 
    L := WizardForm.MainPanel.Left + ScaleX(5); 
    if L > 0 then 
    begin 
    L := 0; 
    KillTimer(0, AnimationTimer); 
    end; 
    WizardForm.MainPanel.Left := L; 
end; 

procedure CurPageChanged(CurPageID: Integer); 
var 
    HoverTimerCallback: LongWord; 
begin 
    if WizardForm.OuterNotebook.ActivePage = WizardForm.InnerPage then 
    begin 
    if not MainPanelAnimated then 
    begin 
     HoverTimerCallback := WrapTimerProc(@AnimationTimerProc, 4); 
     AnimationTimer := SetTimer(0, 0, 5, HoverTimerCallback); 
     WizardForm.MainPanel.Left := -WizardForm.MainPanel.Width; 
     MainPanelAnimated := True; 
    end; 
    end; 
end; 

を使用してコントロールをアニメーション化するためにタイマーを使用することができます右対について

（アニメーションは、画像のショーよりも実際にはよりスムーズです）左のアニメーションは、Inno Setup - Animate a control roll out from right in a determinate pageを参照してください。