ファイルパスの長さをバッチファイルでチェックします。 #stringlength

Question

これは私の最初の投稿です。誰かが私を助けてくれることを願っています。

私はかなり新しい.batファイルですが、私はphpとC++の基本的な知識があります。

次のようなバッチファイルを作成する必要があります。 1.フルファイルパスを含むすべてのファイルを現在のフォルダに表示します。 2.個々のファイルごとのファイルパスを含む、表示されたファイルの長さを表示します。 3.合計ファイル数を表示することがあります。

私は今までこれを書いていますが、ジョブ＃1と＃3はしていますが、文字列の長さを表示できません。

@echo off 
for /r . %%g in (*.*) do (
    echo %%g 
)  
set cnt=0 
for %%A in (*) do set /a cnt+=1 
set /A cnt=cnt-1 
echo Dateien im Verzeichnis = %cnt% 
PAUSE 

文字列またはパスの長さをそれぞれ識別する2つのスクリプトがありますが、最初のスクリプトと一緒に配置できませんでした。ここで

文字列な長さのために1：

@echo off 
set myvar="some string" 
rem compute the length of a string 
set #=%myvar% 
set length=0 
:loop 
if defined # (
    rem shorten string by one character 
    set #=%#:~1% 
    rem increment the string count variable %length% 
    set /A length += 1 
    rem repeat until string is null 
    goto loop 
) 
echo myvar is %length% characters long! 
PAUSE 

そして、ここでは現在のフォルダのパスの長さを表示します作品：

@echo off 
echo %cd%>"%TMP%\Temp.txt" 
for %%l in ("%TMP%\Temp.txt") do set /a len=%%~zl 
del "%TMP%\Temp.txt" 
set /a len-=2 
echo Path length = %len% chars. 
PAUSE 

Answer 1

ここthis :length util functionに基づくソリューションです。バッチスクリプト機能の詳細については、see this pageを参照してください。またread more about delayed expansionにする必要があります。遅延拡張を使用しない場合でも、すべてのスクリプトの先頭にsetlocal ought to be includedがあります。

@echo off 
setlocal 

set "files=0" 

for %%I in (*) do (
    set /a files += 1 
    call :length len "%%~fI" 

    rem // delay expansion of %files% and %len% because of reasons 
    setlocal enabledelayedexpansion 
    echo !files!: %%~fI is !len! characters long. 
    endlocal 
) 

goto :EOF 

:length <return_var> <string> 
setlocal enabledelayedexpansion 
if "%~2"=="" (set ret=0) else set ret=1 
set "tmpstr=%~2" 
for %%I in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if not "!tmpstr:~%%I,1!"=="" (
     set /a ret += %%I 
     set "tmpstr=!tmpstr:~%%I!" 
    ) 
) 
endlocal & set "%~1=%ret%" 
goto :EOF