Outlookでメールをサブフォルダに移動するにはどうすればよいですか？

Question

私のOutlookの受信トレイにあるアイテムを、受信トレイと同じレベルにある別のフォルダのサブフォルダに移動するマクロを作成しようとしています（つまり、親フォルダは受信トレイのサブフォルダではありません）。これは私が使用しているコードです：

Sub EventRequests() 
On Error Resume Next 

Dim ns As Outlook.NameSpace 
Dim moveToFolder As Outlook.MAPIFolder 
Dim objItem As Outlook.MailItem 

Set ns = Application.GetNamespace("MAPI") 

'Define path to the target folder 
Set moveToFolder = ns.Folders("Events").Folders("Event Requests") 

If Application.ActiveExplorer.Selection.Count = 0 Then 
    MsgBox ("Select an E-mail first") 
    Exit Sub 
End If 

If moveToFolder Is Nothing Then 
    MsgBox "Target folder not found!", vbOKOnly + vbExclamation, "Move Macro Error" 
End If 

For Each objItem In Application.ActiveExplorer.Selection 
    If moveToFolder.DefaultItemType = olMailItem Then 
     If objItem.Class = olMail Then 
     objItem.Move moveToFolder 
     End If 
    End If 
Next 

Set objItem = Nothing 
Set moveToFolder = Nothing 
Set ns = Nothing 
End Sub 

私がコードを実行すると、「ターゲットフォルダが見つかりません」というエラーが表示されます。私は Set moveToFolder = ns.GetDefaultFolder(olFolderInbox).Folders("Events").Folders("Event Requests")とSet MoveToFolder = ns.Folders("Mailbox - my name").Folders(targetFolder)を試しましたが、どちらもうまくいきませんでした。私は私の受信トレイのサブフォルダであるフォルダに私の受信トレイにメッセージを移動し、それが正常に動作設定異なるマクロを持っています

Set moveToFolder = ns.GetDefaultFolder(olFolderInbox).Folders("Completed") 

それが正しいサブフォルダを指すように私は、ターゲットパスを修正するにはどうすればよいです？

Answer 1

私は将来的に他の人がこの問題を持っている場合、彼らは私がそれに到着したコードを見ることができるように先に行くと、自分の質問への答えを投稿するつもりは動作します：

Sub EventRequests() 

Dim ns As Outlook.NameSpace 
Dim moveToFolder As Outlook.MAPIFolder 
Dim objItem As Outlook.MailItem 

Set ns = Application.GetNamespace("MAPI") 

On Error GoTo 0 
Set moveToFolder = ns.GetDefaultFolder(olFolderInbox).Parent.Folders("Events").Folders("Event Requests") 


If Application.ActiveExplorer.Selection.Count = 0 Then 
    MsgBox ("Select an E-mail first") 
    Exit Sub 
End If 

If moveToFolder Is Nothing Then 
    MsgBox "Target folder not found!", vbOKOnly + vbExclamation, "Move Macro Error" 
End If 

For Each objItem In Application.ActiveExplorer.Selection 
    If moveToFolder.DefaultItemType = olMailItem Then 
     If objItem.Class = olMail Then 
     objItem.Move moveToFolder 
     End If 
    End If 
Next 

Set objItem = Nothing 
Set moveToFolder = Nothing 
Set ns = Nothing 
End Sub