VBAセルが横にあるときに値を選択する方法と、その値を別のシートの別の列と比較してハイライトする方法

Question

私はvbaでExcelを学習しています。私はここで問題を抱えている。シート1 ColumnCが空になったとき、私はここで達成しようとしています何

はSheet1のColumnBで

1. 値を選択しています。
2. これらの値をとって、それらをsheet2 ColumnOと比較してください。
3. Sheet1 Column2の値と共通する場合、Column1の値は緑色になります。
4. Sheet1 Column1の値と共通しない場合、Sheet1のColumnBの値はsheet1で黄色になります。
5. sheet2 Column1の値は、sheet1に含まれていない場合はsheet2の赤です。ここ

サンプルファイルには、これは私がこれまでに得たものである

https://a.uguu.se/tkGV68TzIGwR_testtt111.xlsx

です。 columnCが空の場合にColumnBの値を選択し、別の列にコピーすることができます。

Sub compareWR() 
Dim emptyI As Long   
Dim emptyJ As Long   
lastrow = ws1.Cells(Rows.Count, "B").End(xlUp).Row 
emptyJ = 2 
For emptyI = 2 To lastrow 
If Cells(emptyI, "C").Value = "" Then 
Cells(emptyJ, "AA").Value = Cells(emptyI, "B").Value 
     emptyJ = emptyJ + 1 
End If 
Next emptyI 
End Sub 

Answer 1

条件付き書式設定のルールは、必要なすべてを処理する必要があります。ここで彼らはVBAにあります。

Option Explicit 

Sub CFRs() 
    Dim addr1 As String, addr2 As String 
    With Worksheets("sheet1") 
     With .Range(.Cells(1, "B"), .Cells(.Rows.Count, "B").End(xlUp)) 
      addr1 = .Cells(1).Address(False, True) 
      addr2 = .Cells(1).Offset(0, 1).Address(False, True) 
      .FormatConditions.Delete 
      With .FormatConditions.Add(Type:=xlExpression, _ 
       Formula1:="=AND(" & addr2 & "=TEXT(,), ISNUMBER(MATCH(" & addr1 & ", Sheet2!$O:$O, 0)))") 
       .Interior.ColorIndex = 10 
      End With 
      With .FormatConditions.Add(Type:=xlExpression, _ 
       Formula1:="=NOT(LEN(" & addr2 & "))") 
       .Interior.ColorIndex = 6 
      End With 
     End With 
    End With 
    With Worksheets("sheet2") 
     With .Range(.Cells(1, "O"), .Cells(.Rows.Count, "O").End(xlUp)) 
      addr1 = .Cells(1).Address(False, True) 
      .FormatConditions.Delete 
      With .FormatConditions.Add(Type:=xlExpression, _ 
       Formula1:="=ISNA(MATCH(" & addr1 & ", Sheet1!$B:$B, 0))") 
       .Interior.ColorIndex = 3 
      End With 
     End With 
    End With 
End Sub